dev-java/netty-tcnative/netty-tcnative-1.1.33.15.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit autotools versionator java-pkg-2 java-pkg-simple
   9
  10 MY_P="${PN}-$(replace_version_separator 3 .Fork)"
  11
  12 DESCRIPTION="Fork of Tomcat Native that incorporates various patches"
  13 HOMEPAGE="http://netty.io/wiki/forked-tomcat-native.html"
  14 SRC_URI="https://github.com/netty/netty-tcnative/archive/${MY_P}.tar.gz"
  15 LICENSE="Apache-2.0"
  16 SLOT="0"
  17 KEYWORDS="~amd64 ~x86"
  18
  19 CDEPEND="dev-libs/apr:1=
  20         dev-libs/openssl:0="
  21
  22 RDEPEND="${CDEPEND}
  23         >=virtual/jre-1.7"
  24
  25 DEPEND="${CDEPEND}
  26         >=virtual/jdk-1.7
  27         app-arch/unzip
  28         dev-java/maven-hawtjni-plugin:0"
  29
  30 S="${WORKDIR}/${PN}-${MY_P}"
  31 JAVA_SRC_DIR="${S}/openssl-dynamic/src/main/java"
  32 NATIVE_DIR="${S}/openssl-dynamic/src/main/native-package"
  33
  34 java_prepare() {
  35         cd "${NATIVE_DIR}" || die
  36         ln -sn ../c src || die
  37         ln -sn . project-template || die
  38
  39         # Provides missing m4 files and Makefile.am template.
  40         unzip -n $(java-pkg_getjars --build-only maven-hawtjni-plugin) project-template/\* || die
  41
  42         sed -i \
  43                 -e "s:@PROJECT_NAME@:${PN}:g" \
  44                 -e "s:@PROJECT_NAME_UNDER_SCORE@:${PN//-/_}:g" \
  45                 -e "s:@PROJECT_SOURCES@:$(echo src/*.c):g" \
  46                 Makefile.am || die
  47
  48         # Avoid dummy version and tedious symlink.
  49         sed -i "s/-release @VERSION@/-avoid-version/g" configure.ac || die
  50
  51         eautoreconf
  52 }
  53
  54 src_configure() {
  55         cd "${NATIVE_DIR}" || die
  56         econf --with-apr=/usr/bin/apr-1-config --with-ssl=/usr
  57 }
  58
  59 src_compile() {
  60         java-pkg-simple_src_compile
  61         emake -C "${NATIVE_DIR}"
  62 }
  63
  64 src_install() {
  65         java-pkg-simple_src_install
  66         java-pkg_doso "${NATIVE_DIR}"/.libs/lib${PN}.so
  67         dodoc README.md
  68 }