dev-java/libmatthew-java/libmatthew-java-0.7.2-r2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit eutils java-pkg-2 flag-o-matic toolchain-funcs
   9
  10 DESCRIPTION="A selection of libraries for Java"
  11 HOMEPAGE="http://www.matthew.ath.cx/projects/java/"
  12 SRC_URI="mirror://gentoo/${P}.tar.gz"
  13
  14 LICENSE="LGPL-2.1"
  15 SLOT="0"
  16 KEYWORDS="amd64 ppc64 x86"
  17
  18 RDEPEND="
  19         >=virtual/jre-1.5"
  20
  21 DEPEND="
  22         >=virtual/jdk-1.5"
  23
  24 PATCHES=( "${FILESDIR}"/${P}-makefile-fixes.patch )
  25 DOCS=( INSTALL changelog README )
  26
  27 src_prepare() {
  28         default
  29         sed -i -e '167d;' cx/ath/matthew/unix/UnixSocket.java || die "sed failed"
  30         rm -v "${S}"/cx/ath/matthew/debug/Debug.java || die "rm failed"
  31 }
  32
  33 src_compile() {
  34         CC=$(tc-getCC) \
  35                 LD=$(tc-getCC) \
  36                 INCLUDES="$(java-pkg_get-jni-cflags)" \
  37                 emake -j1 \
  38                 JARDIR=/usr/share/libmatthew-java/lib \
  39                 JCFLAGS="$(java-pkg_javac-args)" \
  40                 all \
  41                 $(usev doc)
  42 }
  43
  44 src_install() {
  45         java-pkg_newjar cgi-0.5.jar cgi.jar
  46         java-pkg_newjar debug-disable-1.1.jar debug-disable.jar
  47         java-pkg_newjar debug-enable-1.1.jar debug-enable.jar
  48         java-pkg_newjar hexdump-0.2.jar hexdump.jar
  49         java-pkg_newjar io-0.1.jar io.jar
  50         java-pkg_newjar unix-0.5.jar unix.jar
  51         java-pkg_doso libcgi-java.so
  52         java-pkg_doso libunix-java.so
  53         einstalldocs
  54         use source && java-pkg_dosrc cx/
  55         use doc && java-pkg_dojavadoc doc
  56 }