dev-java/jrobin/jrobin-1.6.0-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-pkg-simple
   9
  10 DESCRIPTION="JRobin is a 100% pure Java alternative to RRDTool"
  11 HOMEPAGE="http://www.jrobin.org/"
  12 SRC_URI="https://github.com/OpenNMS/${PN}/archive/${P}-1.tar.gz"
  13
  14 LICENSE="LGPL-2.1"
  15 SLOT="0"
  16 KEYWORDS="amd64 x86"
  17 IUSE="test"
  18 RESTRICT="!test? ( test )"
  19
  20 RDEPEND=">=virtual/jre-1.6"
  21 DEPEND=">=virtual/jdk-1.6
  22         test? ( dev-java/asm:4
  23                 >=dev-java/cglib-3.1:3
  24                 dev-java/easymock:3.2
  25                 dev-java/junit:4
  26                 dev-java/objenesis:0 )"
  27
  28 S="${WORKDIR}/${PN}-${P}-1/src"
  29 JAVA_SRC_DIR="main/java"
  30
  31 java_prepare() {
  32         find "${WORKDIR}" -name "*.jar" -delete || die
  33
  34         # The tests need the resources in this directory for some reason.
  35         mkdir -p test/java/target/classes || die
  36         cd test/java/target/classes || die
  37         ln -snf ../../../../main/resources/* . || die
  38 }
  39
  40 src_compile() {
  41         java-pkg-simple_src_compile
  42         jar uf "${PN}.jar" -C main/resources . || die
  43 }
  44
  45 src_install() {
  46         java-pkg-simple_src_install
  47         java-pkg_dolauncher "${PN}-rrdtool" --main org.jrobin.cmd.RrdCommander
  48 }
  49
  50 src_test() {
  51         cd test/java || die
  52
  53         local CP=".:${S}/${PN}.jar:$(java-pkg_getjars asm-4,cglib-3,easymock-3.2,junit-4,objenesis)"
  54         local TESTS=$(find * -name "*Test.java")
  55         TESTS="${TESTS//.java}"
  56         TESTS="${TESTS//\//.}"
  57
  58         ejavac -cp "${CP}" -d . $(find * -name "*.java")
  59         ejunit4 -classpath "${CP}" ${TESTS}
  60 }
  61
  62 pkg_postinst() {
  63         elog "The rrdtool executable has been installed as ${PN}-rrdtool to"
  64         elog "avoid conflicting with net-analyzer/rrdtool."
  65 }