dev-java/jortho/jortho-1.0.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 JAVA_PKG_IUSE="doc examples source"
   7
   8 inherit java-pkg-2 java-pkg-simple
   9
  10 DESCRIPTION="A Java spell-checking library"
  11 HOMEPAGE="https://www.inetsoftware.de/other-products/jortho"
  12 SRC_URI="mirror://sourceforge/project/jortho/JOrtho%20Library/${PV}/JOrtho_${PV}.zip"
  13
  14 LICENSE="GPL-2"
  15 SLOT="0"
  16 KEYWORDS="amd64 x86"
  17 IUSE=""
  18
  19 RDEPEND="
  20         >=virtual/jre-1.5"
  21 DEPEND="
  22         >=virtual/jdk-1.5
  23         app-arch/unzip"
  24
  25 java_prepare() {
  26         find . -name '*.jar' -exec rm -v {} + || die
  27 }
  28
  29 JAVA_SRC_DIR="src/com"
  30 src_compile() {
  31         mkdir -p target/classes/com/inet/jortho/i18n || die
  32         find src -name '*.properties' \
  33                 -exec cp {} target/classes/com/inet/jortho/i18n \; || die
  34
  35         java-pkg-simple_src_compile
  36 }
  37
  38 src_install() {
  39         java-pkg-simple_src_install
  40
  41         use examples && java-pkg_doexamples src/SampleAppl{et,ication}.java
  42 }