dev-java/jmi-interface/jmi-interface-1.0-r4.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-pkg-simple
   9
  10 JMI_ZIP="jmi-${PV/./_}-fr-interfaces.zip"
  11 MOF_XML="mof-${PV}.xml.bz2"
  12
  13 DESCRIPTION="Java Metadata Interface Sample Class Interface"
  14 HOMEPAGE="http://java.sun.com/products/jmi/"
  15 SRC_URI="mirror://gentoo/${JMI_ZIP}
  16                  mirror://gentoo/${MOF_XML}"
  17
  18 LICENSE="sun-bcla-jmi"
  19 SLOT="0"
  20 KEYWORDS="amd64 x86"
  21
  22 RDEPEND="
  23         >=virtual/jre-1.6"
  24
  25 DEPEND="
  26         >=virtual/jdk-1.6
  27         source? ( app-arch/zip )"
  28
  29 JAVA_SRC_DIR="src"
  30
  31 src_unpack() {
  32         mkdir "${S}/src" || die
  33         cd "${S}/src" || die
  34         unpack ${JMI_ZIP}
  35
  36         # adding mof.xml required by Netbeans
  37         # #98603 and #162328
  38         cd "${S}/src/javax/jmi/model" || die
  39         unpack ${MOF_XML}
  40         cp mof-1.0.xml mof.xml || die
  41 }
  42
  43 java_prepare() {
  44         # rename enum keywords because javadoc hates them
  45         # even with -source 1.4, bummer
  46         epatch "${FILESDIR}/${P}-enum.patch"
  47 }
  48
  49 src_compile() {
  50         java-pkg-simple_src_compile
  51         java-pkg_addres "${PN}.jar" src -name "*.xml"
  52 }