dev-java/jgoodies-animation/jgoodies-animation-1.2.0-r2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 JAVA_PKG_IUSE="doc examples source test"
   7
   8 inherit java-pkg-2 java-ant-2
   9
  10 MY_V=${PV//./_}
  11
  12 DESCRIPTION="JGoodies Animation Library"
  13 HOMEPAGE="http://www.jgoodies.com/"
  14 SRC_URI="mirror://gentoo/${P}.zip"
  15
  16 LICENSE="BSD"
  17 SLOT="0"
  18 KEYWORDS="amd64 x86"
  19
  20 DEPEND="
  21         app-arch/unzip
  22         >=virtual/jdk-1.6
  23         test? ( dev-java/ant-junit:0 )"
  24
  25 RDEPEND="
  26         >=virtual/jre-1.6
  27         examples? (
  28                 >=dev-java/jgoodies-binding-1.1:1.0
  29                 >=dev-java/jgoodies-forms-1.0:0
  30         )"
  31
  32 S="${WORKDIR}/animation-${PV}"
  33
  34 EANT_FILTER_COMPILER="jikes"
  35 EANT_DOC_TARGET=""
  36
  37 DOCS=( RELEASE-NOTES.txt README.html )
  38
  39 src_prepare() {
  40         default
  41
  42         java-pkg_clean
  43 }
  44
  45 src_test() {
  46         eant test -Djunit.jar.present=true \
  47                 -Djunit.jar=$(java-pkg_getjar junit junit.jar)
  48 }
  49
  50 src_install() {
  51         java-pkg_dojar build/animation.jar
  52         einstalldocs
  53         use doc && java-pkg_dohtml -r docs/*
  54         use source && java-pkg_dosrc src/core/*
  55         use examples && java-pkg_doexamples src/tutorial
  56 }