dev-java/java-service-wrapper/java-service-wrapper-3.5.25-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5 JAVA_PKG_IUSE="doc source test"
   6
   7 inherit eutils java-pkg-2 java-ant-2 toolchain-funcs
   8
   9 MY_PN="wrapper"
  10 MY_P="${MY_PN}_${PV}_src"
  11 DESCRIPTION="A wrapper that makes it possible to install a Java Application as daemon"
  12 HOMEPAGE="http://wrapper.tanukisoftware.org/"
  13 SRC_URI="http://${MY_PN}.tanukisoftware.org/download/${PV}/${MY_P}.tar.gz"
  14
  15 LICENSE="tanuki-community"
  16 SLOT="0"
  17 KEYWORDS="amd64 x86"
  18 IUSE=""
  19
  20 RDEPEND="
  21         >=virtual/jre-1.4"
  22 DEPEND="
  23         >=virtual/jdk-1.4
  24         test? (
  25                 dev-java/ant-junit:0
  26         )"
  27
  28 S="${WORKDIR}/${MY_P}"
  29
  30 JAVA_ANT_REWRITE_CLASSPATH="true"
  31
  32 PATCHES=(
  33         "${FILESDIR}"/${P}-as-needed.patch
  34         "${FILESDIR}"/${P}-gentoo-wrapper-defaults.patch
  35         "${FILESDIR}"/${P}-testsuite.patch
  36 )
  37
  38 java_prepare() {
  39         epatch "${PATCHES[@]}"
  40
  41         cp "${S}/src/c/Makefile-linux-armel-32.make" "${S}/src/c/Makefile-linux-arm-32.make"
  42 }
  43
  44 src_compile() {
  45         tc-export CC
  46         BITS="32"
  47         use amd64 && BITS="64"
  48         eant -Dbits=${BITS} jar compile-c
  49         if use doc; then
  50                 ejavadoc -d api -sourcepath src/java/ -subpackages org \
  51                         || die "javadoc failed"
  52         fi
  53 }
  54
  55 src_test() {
  56         ANT_TASKS="ant-junit" eant -Dbits="${BITS}" test
  57 }
  58
  59 src_install() {
  60         java-pkg_dojar lib/wrapper.jar
  61         java-pkg_doso lib/libwrapper.so
  62
  63         dobin bin/wrapper
  64         dodoc README*.txt
  65         dodoc doc/revisions.txt
  66
  67         use doc && java-pkg_dojavadoc api
  68         use source && java-pkg_dosrc src/java/*
  69 }