dev-java/janino/janino-2.7.0.ebuild

   1 # Copyright 1999-2013 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 JAVA_PKG_IUSE="doc source examples"
   7
   8 inherit java-pkg-2 java-pkg-simple
   9
  10 DESCRIPTION="An embedded compiler for run-time compilation purposes"
  11 HOMEPAGE="http://janino.net/"
  12 SRC_URI="http://janino.net/download/${P}.zip"
  13
  14 LICENSE="BSD"
  15 SLOT="0"
  16 KEYWORDS="amd64 x86"
  17
  18 IUSE=""
  19
  20 CDEPEND="dev-java/ant-core:0
  21         dev-java/unkrig-nullanalysis:0"
  22 RDEPEND=">=virtual/jre-1.6
  23         ${CDEPEND}"
  24 DEPEND=">=virtual/jdk-1.6
  25         app-arch/unzip
  26         ${CDEPEND}"
  27
  28 S="${WORKDIR}/${P}"
  29 JAVA_SRC_DIR="src"
  30 JAVA_GENTOO_CLASSPATH="ant-core,unkrig-nullanalysis"
  31
  32 java_prepare() {
  33         unzip "${S}"/janino-src.zip -d ${JAVA_SRC_DIR} && \
  34         unzip "${S}"/commons-compiler-src.zip -d ${JAVA_SRC_DIR} || die
  35         find -iname '*.jar' -delete || die
  36
  37         mkdir -p target/classes && \
  38                 mv src/org.codehaus.commons.compiler.properties target/classes || die
  39
  40         mkdir examples || die
  41         mv src/org/codehaus/commons/compiler/samples/* examples/ || die
  42 }
  43
  44 src_install() {
  45         java-pkg-simple_src_install
  46         use examples && java-pkg_doexamples examples/
  47 }