dev-java/jamon/jamon-2.81.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 MY_PN="${PN}api"
   7 MY_PV="${PV//./_}"
   8 MY_P="${MY_PN}-${MY_PV}"
   9
  10 JAVA_PKG_IUSE="doc source"
  11
  12 inherit java-pkg-2 java-pkg-simple
  13
  14 DESCRIPTION="Java API to monitor production applications"
  15 HOMEPAGE="http://www.jamonapi.com/"
  16 SRC_URI="https://github.com/stevensouza/${MY_PN}/archive/v${MY_PV}.tar.gz -> ${MY_P}.tar.gz"
  17 LICENSE="BSD"
  18 SLOT="2"
  19 KEYWORDS="~amd64 ~x86"
  20 IUSE="test"
  21 RESTRICT="!test? ( test )"
  22
  23 CDEPEND="dev-java/log4j:0
  24         java-virtuals/interceptor-api:0
  25         java-virtuals/servlet-api:3.0
  26         www-servers/tomcat:7"
  27
  28 RDEPEND="${CDEPEND}
  29         >=virtual/jre-1.7
  30         dev-db/hsqldb:0
  31         dev-java/jakarta-oro:2.0"
  32
  33 DEPEND="${CDEPEND}
  34         >=virtual/jdk-1.7
  35         test? (
  36                 dev-db/hsqldb:0
  37                 dev-java/assertj-core:2
  38                 dev-java/junit:4
  39                 dev-java/mockito:0
  40                 dev-java/objenesis:0
  41         )"
  42
  43 S="${WORKDIR}/${MY_P}"
  44 JAVA_GENTOO_CLASSPATH="interceptor-api,log4j,servlet-api-3.0,tomcat-7"
  45 JAVA_SRC_DIR="${PN}/src/main/java"
  46 WAR_DIR="jamon_war/src/main/webapp"
  47
  48 java_prepare() {
  49         # No Jetty or Hazelcast packaged right now and Spring is ancient.
  50         find \( -name "*Jetty*.java" -o -name "*Hazelcast*.java" \) -exec rm -v {} + || die
  51         rm -rv ./jamon/src/test/java/com/jamonapi/distributed/JamonDataPersisterFactoryTest.java \
  52                 ./jamon/src/{main,test}/java/com/jamonapi/aop/spring || die
  53
  54         # Keep fdsapi and xss-html-filter bundled as we lack packages.
  55         rm -v ${WAR_DIR}/WEB-INF/lib/{hsqldb,jakarta-oro}*.jar || die
  56 }
  57
  58 src_compile() {
  59         java-pkg-simple_src_compile
  60         jar cf ${PN}.war -C ${WAR_DIR} . || die
  61 }
  62
  63 src_install() {
  64         java-pkg-simple_src_install
  65         java-pkg_dowar ${PN}.war
  66         dodoc designnotes.txt README.md
  67
  68         # hsqldb used by JSP files, oro used by fdsapi.
  69         java-pkg_register-dependency hsqldb,jakarta-oro-2.0
  70 }
  71
  72 src_test() {
  73         cd jamon/src/test/java || die
  74
  75         local CP=".:../resources:${S}/${PN}.jar:$(java-pkg_getjars assertj-core-2,hsqldb,junit-4,mockito,objenesis,${JAVA_GENTOO_CLASSPATH})"
  76         local TESTS=$(find * -name "*Test.java")
  77         TESTS="${TESTS//.java}"
  78         TESTS="${TESTS//\//.}"
  79
  80         ejavac -cp "${CP}" -d . $(find * -name "*.java")
  81         ejunit4 -classpath "${CP}" ${TESTS}
  82 }