dev-java/jackson/jackson-2.9.10.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-pkg-simple
   9
  10 DESCRIPTION="High-performance JSON processor"
  11 HOMEPAGE="https://github.com/FasterXML/jackson-core"
  12 SRC_URI="https://github.com/FasterXML/${PN}-core/archive/${PN}-core-${PV}.tar.gz"
  13 LICENSE="Apache-2.0"
  14 SLOT="2"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE="test"
  17 RESTRICT="!test? ( test )"
  18
  19 RDEPEND=">=virtual/jre-1.7"
  20 DEPEND=">=virtual/jdk-1.7
  21         test? ( dev-java/junit:4 )"
  22
  23 S="${WORKDIR}/${PN}-core-${PN}-core-${PV}"
  24 JAVA_SRC_DIR="src/main/java"
  25
  26 src_prepare() {
  27         default
  28
  29         sed -e 's:@package@:com.fasterxml.jackson.core.json:g' \
  30                 -e "s:@projectversion@:${PV}:g" \
  31                 -e 's:@projectgroupid@:com.fasterxml.jackson.core:g' \
  32                 -e 's:@projectartifactid@:jackson-core:g' \
  33                 "${JAVA_SRC_DIR}/com/fasterxml/jackson/core/json/PackageVersion.java.in" \
  34                 > "${JAVA_SRC_DIR}/com/fasterxml/jackson/core/json/PackageVersion.java" || die
  35
  36         java-pkg-2_src_prepare
  37 }
  38
  39 src_compile() {
  40         java-pkg-simple_src_compile
  41         java-pkg_addres ${PN}.jar src/main/resources
  42 }
  43
  44 src_install() {
  45         java-pkg-simple_src_install
  46         dodoc README.md release-notes/{CREDITS,VERSION}-2.x
  47 }
  48
  49 src_test() {
  50         cd src/test/java || die
  51
  52         local CP=".:../resources:${S}/${PN}.jar:$(java-pkg_getjars junit-4)"
  53         local TESTS=$(find * -name "Test*.java")
  54         TESTS="${TESTS//.java}"
  55         TESTS="${TESTS//\//.}"
  56
  57         ejavac -cp "${CP}" -d . $(find * -name "*.java")
  58         ejunit4 -classpath "${CP}" ${TESTS}
  59 }