dev-java/icedtea-web/icedtea-web-1.6.1-r1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 README_GENTOO_SUFFIX="-r1"
   7
   8 inherit autotools eutils multilib readme.gentoo-r1 java-pkg-2 xdg-utils
   9
  10 DESCRIPTION="FOSS Java browser plugin and Web Start implementation"
  11 HOMEPAGE="http://icedtea.classpath.org"
  12 SRC_URI="http://icedtea.classpath.org/download/source/${P}.tar.gz"
  13 LICENSE="GPL-2 GPL-2-with-linking-exception LGPL-2"
  14 SLOT="0"
  15 KEYWORDS="amd64 ~arm ppc64 x86"
  16 IUSE="doc javascript nsplugin tagsoup test"
  17 RESTRICT="test"
  18
  19 CDEPEND="javascript? ( dev-java/rhino:1.6 )
  20         nsplugin? ( >=dev-libs/glib-2.16:2= )
  21         tagsoup? ( dev-java/tagsoup:0 )"
  22
  23 DEPEND="${CDEPEND}
  24         app-arch/zip
  25         >=virtual/jdk-1.7
  26         virtual/pkgconfig
  27         nsplugin? ( net-misc/npapi-sdk )
  28         test? ( >=dev-java/junit-4.8:4 )"
  29
  30 RDEPEND="${CDEPEND}
  31         >=app-eselect/eselect-java-0.2.0
  32         >=virtual/jre-1.7
  33         nsplugin? (
  34                 !dev-java/oracle-jdk-bin[nsplugin]
  35                 !dev-java/oracle-jre-bin[nsplugin]
  36         )"
  37
  38 src_prepare() {
  39         # http://icedtea.classpath.org/bugzilla/show_bug.cgi?id=2779
  40         # http://icedtea.classpath.org/bugzilla/show_bug.cgi?id=2780
  41         # http://icedtea.classpath.org/bugzilla/show_bug.cgi?id=2855
  42         epatch "${FILESDIR}"/${PN}-1.6-{javadoc,no-hg,launchers,respect-ldflags,unused-libs}.patch
  43
  44         if java-pkg_is-vm-version-ge "1.8" ; then
  45                 sed -i 's/JAVADOC_OPTS=/\0-Xdoclint:none /g' Makefile.am || die
  46         fi
  47
  48         eautoreconf
  49 }
  50
  51 src_configure() {
  52         local tagsoup
  53         use tagsoup && tagsoup="$(java-pkg_getjars tagsoup)"
  54
  55         local config=(
  56                 # Rename javaws to itweb-javaws as eselect java-vm manages
  57                 # javaws to prevent a clash with Oracle's implementation.
  58                 --program-transform-name='s/^javaws$/itweb-javaws/'
  59                 --libdir="${EPREFIX}"/usr/$(get_libdir)/nsbrowser/plugins
  60                 --with-java="${EPREFIX}"/usr/bin/java
  61                 --with-jdk-home="${JAVA_HOME}"
  62                 $(use_enable doc docs)
  63                 $(use_enable nsplugin plugin)
  64                 $(use_with javascript rhino)
  65                 $(use_with tagsoup tagsoup "${tagsoup}")
  66         )
  67
  68         # See bug #573060.
  69         xdg_environment_reset
  70
  71         # Rely on the --with-jdk-home option given above.
  72         unset JAVA_HOME JDK_HOME CLASSPATH JAVAC JAVACFLAGS
  73
  74         econf "${config[@]}"
  75 }
  76
  77 src_compile() {
  78         default
  79 }
  80
  81 src_install() {
  82         default
  83         readme.gentoo_create_doc
  84 }
  85
  86 pkg_postinst() {
  87         readme.gentoo_print_elog
  88 }