dev-java/htmlcleaner/htmlcleaner-2.13.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-pkg-simple
   9
  10 DESCRIPTION="HTML parser written in Java that can be used as a tool, library or Ant task"
  11 HOMEPAGE="http://htmlcleaner.sourceforge.net/"
  12 SRC_URI="mirror://sourceforge/htmlcleaner/files/${P}-src.zip"
  13
  14 LICENSE="BSD"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~x86"
  17 IUSE="test"
  18 RESTRICT="!test? ( test )"
  19
  20 CDEPEND="dev-java/jdom:2"
  21
  22 RDEPEND="
  23         ${CDEPEND}
  24         >=virtual/jre-1.5"
  25
  26 DEPEND="
  27         ${CDEPEND}
  28         app-arch/unzip
  29         dev-java/ant-core:0
  30         test? ( dev-java/junit:4 )
  31         >=virtual/jdk-1.5"
  32
  33 JAVA_SRC_DIR="src/main/java"
  34 JAVA_GENTOO_CLASSPATH="jdom-2"
  35
  36 src_prepare() {
  37         # Don't require default.xml to be in the current directory.
  38         sed -i "s:\"default\.xml\":\"${JAVA_PKG_SHAREPATH}/default.xml\":g" \
  39                 src/main/java/org/htmlcleaner/ConfigFileTagProvider.java || die
  40 }
  41
  42 src_configure() {
  43         JAVA_GENTOO_CLASSPATH_EXTRA=$(java-pkg_getjars --build-only ant-core)
  44 }
  45
  46 src_install() {
  47         java-pkg-simple_src_install
  48         java-pkg_register-ant-task
  49         java-pkg_dolauncher ${PN} --main org.${PN}.CommandLine
  50
  51         insinto "${JAVA_PKG_SHAREPATH}"
  52         newins example.xml default.xml
  53 }
  54
  55 src_test() {
  56         local DIR="src/test/java"
  57         local CP="${DIR}:${PN}.jar:$(java-pkg_getjars junit-4,${JAVA_GENTOO_CLASSPATH})"
  58
  59         local TESTS=$(find "${DIR}" -name "*Test.java" ! -name "Abstract*")
  60         TESTS="${TESTS//src\/test\/java\/}"
  61         TESTS="${TESTS//.java}"
  62         TESTS="${TESTS//\//.}"
  63
  64         ejavac -classpath "${CP}" -d "${DIR}" $(find "${DIR}" -name "*.java")
  65         ejunit4 -classpath "${CP}" ${TESTS}
  66 }