dev-java/hamcrest-generator/hamcrest-generator-1.3-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 JAVA_PKG_IUSE="source test"
   7
   8 inherit java-pkg-2 java-ant-2
   9
  10 MY_PN="hamcrest"
  11 MY_P="${MY_PN}-${PV}"
  12 S="${WORKDIR}/${MY_P}"
  13
  14 DESCRIPTION="Code generator for Hamcrest's library of matchers for building test expressions"
  15 HOMEPAGE="https://github.com/hamcrest"
  16 SRC_URI="https://${MY_PN}.googlecode.com/files/${MY_P}.tgz"
  17
  18 LICENSE="BSD-2"
  19 SLOT="${PV}"
  20 KEYWORDS="amd64 ~arm arm64 ppc64 x86 ~ppc-macos ~x64-macos ~x86-macos"
  21
  22 CDEPEND=">=dev-java/qdox-1.12-r1:1.12"
  23
  24 DEPEND=">=virtual/jdk-1.5
  25         userland_GNU? ( sys-apps/findutils )
  26         ${CDEPEND}"
  27
  28 RDEPEND=">=virtual/jre-1.5
  29         ${CDEPEND}"
  30
  31 EANT_BUILD_TARGET="generator"
  32 EANT_EXTRA_ARGS="-Dversion=${PV}"
  33
  34 java_prepare() {
  35         # Don't include source in JAR.  If a Gentoo user wants the source the source
  36         # USE flag will be enabled.
  37         epatch "${FILESDIR}/${P}-no_jarjar.patch"
  38
  39         find -iname "*.jar" -exec rm -v {} + || die "Unable to remove bundled JAR files"
  40
  41         # These jars must be symlinked.  Specifying them using gentoo.classpath
  42         # does not work.
  43         java-pkg_jar-from --into lib/generator qdox-1.12 qdox.jar qdox-1.12.jar
  44 }
  45
  46 src_install() {
  47         java-pkg_newjar build/${PN}-nodeps-${PV}.jar ${PN}.jar
  48
  49         dodoc README.txt CHANGES.txt
  50
  51         use source && java-pkg_dosrc ${PN}/src/main/java/org
  52 }