dev-java/hamcrest-core/hamcrest-core-1.3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-ant-2
   9
  10 MY_PN="hamcrest"
  11 MY_P="${MY_PN}-${PV}"
  12 S="${WORKDIR}/${MY_P}"
  13
  14 DESCRIPTION="Core library of matchers for building test expressions"
  15 HOMEPAGE="https://github.com/hamcrest"
  16 SRC_URI="https://${MY_PN}.googlecode.com/files/${MY_P}.tgz"
  17
  18 LICENSE="BSD-2"
  19 SLOT="${PV}"
  20 KEYWORDS="amd64 ~arm arm64 ppc64 x86 ~ppc-macos ~x64-macos ~x86-macos"
  21
  22 DEPEND=">=virtual/jdk-1.5
  23         ~dev-java/hamcrest-generator-${PV}
  24         userland_GNU? ( sys-apps/findutils )"
  25
  26 RDEPEND=">=virtual/jre-1.5"
  27
  28 JAVA_ANT_REWRITE_CLASSPATH="true"
  29 JAVA_ANT_CLASSPATH_TAGS="${JAVA_ANT_CLASSPATH_TAGS} java java-to-jar"
  30
  31 EANT_BUILD_TARGET="core"
  32
  33 java_prepare() {
  34         # Empty out the contents of the generator target; it has already been built.
  35         epatch "${FILESDIR}/hamcrest-1.3-empty_generator.patch"
  36
  37         # Fix problems with Javadoc target.
  38         epatch "${FILESDIR}/hamcrest-core-1.3-fix_javadoc.patch"
  39
  40         find -iname "*.jar" -exec rm -v {} + || die "Unable to clean bundled JAR files"
  41
  42         local cp="build/${P}.jar"
  43         cp="${cp}:$(java-pkg_getjars --build-only --with-dependencies hamcrest-generator-${SLOT})"
  44         EANT_EXTRA_ARGS="-Dversion=${PV} -Dgentoo.classpath=${cp}"
  45 }
  46
  47 src_install() {
  48         java-pkg_newjar build/${PN}-${PV}.jar ${PN}.jar
  49
  50         dodoc README.txt CHANGES.txt
  51
  52         use doc && java-pkg_dojavadoc build/temp/hamcrest-all-${PV}-javadoc.jar.contents
  53         use source && java-pkg_dosrc ${PN}/src/main/java/org
  54 }