dev-java/freemarker/freemarker-2.3.25.ebuild

   1 # Copyright 1999-2018 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 MY_PN="incubator-${PN}"
   7 JAVA_PKG_IUSE="doc source"
   8
   9 inherit java-pkg-2 java-ant-2
  10
  11 DESCRIPTION="A Java tool to generate text output based on templates"
  12 HOMEPAGE="http://freemarker.org/"
  13 SRC_URI="https://github.com/apache/${MY_PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  14 LICENSE="Apache-2.0"
  15 SLOT="2.3"
  16 KEYWORDS="amd64 x86"
  17
  18 CP_DEPEND="dev-java/avalon-logkit:2.0
  19         dev-java/commons-logging:0
  20         dev-java/dom4j:1
  21         dev-java/jaxen:1.1
  22         dev-java/jython:2.7
  23         dev-java/log4j:0
  24         dev-java/rhino:1.6
  25         dev-java/slf4j-api:0
  26         dev-java/xalan:0
  27         java-virtuals/servlet-api:2.5"
  28
  29 RDEPEND="${CP_DEPEND}
  30         >=virtual/jre-1.7"
  31
  32 DEPEND="${CP_DEPEND}
  33         >=virtual/jdk-1.7
  34         dev-java/javacc:0"
  35
  36 S="${WORKDIR}/${MY_PN}-${PV}"
  37
  38 PATCHES=(
  39         "${FILESDIR}"/build.xml.patch
  40 )
  41
  42 EANT_BUILD_TARGET="compile"
  43 EANT_EXTRA_ARGS="-Ddeps.available=true"
  44 JAVA_ANT_REWRITE_CLASSPATH="true"
  45
  46 src_prepare() {
  47         default
  48
  49         rm -rv \
  50            src/main/java/freemarker/ext/jdom \
  51            src/main/java/freemarker/ext/xml/_JdomNavigator.java \
  52            src/main/java/freemarker/ext/beans/JRebelClassChangeNotifier.java || die
  53
  54         sed -i \
  55                 -e '/<ivy:cachepath/d' \
  56                 -e 's/"ivy\.dep[^"]*"/"gentoo.classpath"/g' \
  57                 -e "s:javacchome=\"[^\"]*\":javacchome=\"${EROOT}usr/share/javacc/lib\":g" \
  58                 build.xml || die
  59
  60         java-pkg-2_src_prepare
  61 }
  62
  63 src_install() {
  64         jar cf ${PN}.jar -C build/classes . || die
  65         java-pkg_dojar ${PN}.jar
  66
  67         dodoc README
  68         use doc && java-pkg_dojavadoc build/api
  69 }