dev-java/freehep-graphics2d/freehep-graphics2d-2.4.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 CHARTABLE_PN="freehep-chartable-converter-plugin"
   7 CHARTABLE_P="${CHARTABLE_PN}-2.2.1"
   8
   9 MY_PN="freehep-vectorgraphics"
  10 MY_P="${MY_PN}-${PV}"
  11
  12 JAVA_PKG_IUSE="doc source"
  13
  14 inherit java-pkg-2 java-pkg-simple
  15
  16 DESCRIPTION="High Energy Physics Java library - FreeHEP Graphics 2D Library"
  17 HOMEPAGE="http://java.freehep.org/"
  18 SRC_URI="https://github.com/freehep/${MY_PN}/archive/${MY_P}.tar.gz
  19         https://github.com/freehep/${CHARTABLE_PN}/archive/${CHARTABLE_P}.tar.gz"
  20 LICENSE="Apache-2.0 LGPL-2.1"
  21 SLOT="0"
  22 KEYWORDS="~amd64 ~x86"
  23 IUSE="test"
  24 RESTRICT="!test? ( test )"
  25
  26 CDEPEND="~dev-java/freehep-graphicsbase-${PV}:${SLOT}"
  27
  28 DEPEND="${CDEPEND}
  29         >=virtual/jdk-1.7
  30         test? ( dev-java/junit:4 )"
  31
  32 RDEPEND="${CDEPEND}
  33         >=virtual/jre-1.7"
  34
  35 S="${WORKDIR}/${MY_PN}-${MY_P}/${PN}"
  36 JAVA_SRC_DIR="src/main/java"
  37 JAVA_GENTOO_CLASSPATH="freehep-graphicsbase"
  38
  39 src_compile() {
  40         # This package uses a custom Maven plugin to generate some
  41         # sources. We're not using Maven but we can run it manually. We
  42         # could package the plugin separately but it's not used elsewhere.
  43
  44         local SRC ENC CP="${WORKDIR}"/${CHARTABLE_PN}-${CHARTABLE_P}/src/main/java CLASS=org/freehep/graphics2d/font/encoding/CharTableConverter
  45         ejavac "${CP}/${CLASS}.java"
  46
  47         for SRC in src/main/encoding/{Expert,Symbol,Zapfdingbats}.utf-16; do
  48                 ebegin "Converting ${SRC}"
  49                 java -cp "${CP}" ${CLASS} ${JAVA_SRC_DIR} org.freehep.graphics2d.font ${SRC} || die
  50                 eend $?
  51         done
  52
  53         SRC=src/main/encoding/Latin.utf-16
  54
  55         for ENC in ISO MAC WIN PDF STD; do
  56                 ebegin "Converting ${SRC} (${ENC})"
  57                 java -cp "${CP}" ${CLASS} ${JAVA_SRC_DIR} org.freehep.graphics2d.font ${SRC} ${ENC} || die
  58                 eend $?
  59         done
  60
  61         java-pkg-simple_src_compile
  62 }
  63
  64 src_test() {
  65         local DIR=src/test/java
  66         local CP="${DIR}:${PN}.jar:$(java-pkg_getjars junit-4,${JAVA_GENTOO_CLASSPATH})"
  67         local TESTS=$(find ${DIR} -name "Test*.java")
  68         TESTS="${TESTS//src\/test\/java\/}"
  69         TESTS="${TESTS//.java}"
  70         TESTS="${TESTS//\//.}"
  71
  72         ejavac -cp "${CP}" -d ${DIR} $(find ${DIR} -name "*.java")
  73         ejunit4 -classpath "${CP}" ${TESTS}
  74 }