dev-java/commons-logging/commons-logging-1.2-r2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-ant-2 java-osgi
   9
  10 DESCRIPTION="An ultra-thin bridge between different Java logging libraries"
  11 HOMEPAGE="https://commons.apache.org/logging/"
  12 SRC_URI="mirror://apache/commons/logging/source/${P}-src.tar.gz"
  13
  14 LICENSE="Apache-2.0"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  17 IUSE="avalon-framework avalon-logkit log4j servletapi test"
  18 RESTRICT="!test? ( test ) !servletapi? ( test )"
  19
  20 CDEPEND="
  21         log4j? ( dev-java/log4j:0 )
  22         servletapi? ( java-virtuals/servlet-api:3.1 )
  23         avalon-logkit? ( dev-java/avalon-logkit:2.0 )
  24         avalon-framework? ( dev-java/avalon-framework:4.2 )"
  25
  26 RDEPEND="
  27         ${CDEPEND}
  28         >=virtual/jre-1.6"
  29
  30 DEPEND="
  31         ${CDEPEND}
  32         >=virtual/jdk-1.6
  33         test? ( dev-java/ant-junit:0 )"
  34
  35 S="${WORKDIR}/${P}-src"
  36
  37 EANT_BUILD_TARGET="compile"
  38 JAVA_ANT_REWRITE_CLASSPATH="yes"
  39 JAVA_ANT_IGNORE_SYSTEM_CLASSES="yes"
  40
  41 DOCS=( RELEASE-NOTES.txt PROPOSAL.html )
  42
  43 src_prepare() {
  44         default
  45
  46         eapply "${FILESDIR}/${P}-gentoo.patch"
  47         # patch to make the build.xml respect no servletapi
  48         eapply "${FILESDIR}/${P}-servletapi.patch"
  49
  50         # bug #208098
  51         echo "jdk.1.4.present=true" > build.properties || die
  52
  53         if use avalon-framework; then
  54                 echo "avalon-framework.jar=$(java-pkg_getjars avalon-framework-4.2)" >> build.properties || die
  55         fi
  56         if use avalon-logkit; then
  57                 echo "logkit.jar=$(java-pkg_getjars avalon-logkit-2.0)" >> build.properties || die
  58         fi
  59         if use log4j; then
  60                 echo "log4j12.jar=$(java-pkg_getjars log4j)" >> build.properties || die
  61         fi
  62
  63         if use servletapi; then
  64                 echo "servletapi.jar=$(java-pkg_getjar --virtual servlet-api-3.1 servlet-api.jar)" >> build.properties || die
  65         fi
  66 }
  67
  68 src_install() {
  69         local pkg=org.apache.commons.logging
  70         java-osgi_newjar "target/${P}.jar" "${pkg}" "Apache Commons Logging" "${pkg};version=\"${PV}\", ${pkg}.impl;version=\"${PV}\""
  71         java-pkg_newjar target/${PN}-api-${PV}.jar ${PN}-api.jar
  72         java-pkg_newjar target/${PN}-adapters-${PV}.jar ${PN}-adapters.jar
  73
  74         einstalldocs
  75         use doc && java-pkg_dojavadoc target/docs/
  76         use source && java-pkg_dosrc src/main/java/org
  77 }
  78
  79 src_test() {
  80         java-pkg-2_src_test
  81 }