dev-java/commons-logging/commons-logging-1.2-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-ant-2 java-osgi
   9
  10 DESCRIPTION="An ultra-thin bridge between different Java logging libraries"
  11 HOMEPAGE="http://commons.apache.org/logging/"
  12 SRC_URI="mirror://apache/commons/logging/source/${P}-src.tar.gz"
  13 LICENSE="Apache-2.0"
  14 SLOT="0"
  15 KEYWORDS="amd64 ~arm64 ppc64 x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  16 IUSE="avalon-framework avalon-logkit log4j servletapi test"
  17 RESTRICT="!servletapi? ( test )"
  18
  19 CDEPEND="avalon-framework? ( dev-java/avalon-framework:4.2 )
  20         avalon-logkit? ( dev-java/avalon-logkit:2.0 )
  21         log4j? ( dev-java/log4j:0 )
  22         servletapi? ( java-virtuals/servlet-api:3.1 )"
  23
  24 RDEPEND="${CDEPEND}
  25         >=virtual/jre-1.6"
  26
  27 DEPEND="${CDEPEND}
  28         >=virtual/jdk-1.6
  29         test? ( dev-java/ant-junit:0 )"
  30
  31 S="${WORKDIR}/${P}-src"
  32
  33 EANT_BUILD_TARGET="compile"
  34 JAVA_ANT_REWRITE_CLASSPATH="yes"
  35 JAVA_ANT_IGNORE_SYSTEM_CLASSES="yes"
  36
  37 java_prepare() {
  38         epatch "${FILESDIR}/${P}-gentoo.patch"
  39         # patch to make the build.xml respect no servletapi
  40         epatch "${FILESDIR}/${P}-servletapi.patch"
  41
  42         # bug #208098
  43         echo "jdk.1.4.present=true" > build.properties
  44
  45         use avalon-framework && echo "avalon-framework.jar=$(java-pkg_getjars avalon-framework-4.2)" >> build.properties
  46         use avalon-logkit && echo "logkit.jar=$(java-pkg_getjars avalon-logkit-2.0)" >> build.properties
  47         use log4j && echo "log4j12.jar=$(java-pkg_getjars log4j)" >> build.properties
  48         use servletapi && echo "servletapi.jar=$(java-pkg_getjar --virtual servlet-api-3.1 servlet-api.jar)" >> build.properties
  49 }
  50
  51 src_install() {
  52         local pkg=org.apache.commons.logging
  53         java-osgi_newjar "target/${P}.jar" "${pkg}" "Apache Commons Logging" "${pkg};version=\"${PV}\", ${pkg}.impl;version=\"${PV}\""
  54         java-pkg_newjar target/${PN}-api-${PV}.jar ${PN}-api.jar
  55         java-pkg_newjar target/${PN}-adapters-${PV}.jar ${PN}-adapters.jar
  56
  57         dodoc RELEASE-NOTES.txt || die
  58         dohtml PROPOSAL.html || die
  59         use doc && java-pkg_dojavadoc target/docs/
  60         use source && java-pkg_dosrc src/main/java/org
  61 }
  62
  63 src_test() {
  64         java-pkg-2_src_test
  65 }