dev-java/commons-logging/commons-logging-1.2-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-ant-2 java-osgi
   9
  10 DESCRIPTION="An ultra-thin bridge between different Java logging libraries"
  11 HOMEPAGE="https://commons.apache.org/logging/"
  12 SRC_URI="mirror://apache/commons/logging/source/${P}-src.tar.gz"
  13
  14 LICENSE="Apache-2.0"
  15 SLOT="0"
  16 KEYWORDS="amd64 ~arm64 ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  17 IUSE="avalon-framework avalon-logkit log4j servletapi test"
  18 RESTRICT="!test? ( test ) !servletapi? ( test )"
  19
  20 CDEPEND="avalon-framework? ( dev-java/avalon-framework:4.2 )
  21         avalon-logkit? ( dev-java/avalon-logkit:2.0 )
  22         log4j? ( dev-java/log4j:0 )
  23         servletapi? ( java-virtuals/servlet-api:3.1 )"
  24
  25 RDEPEND="
  26         ${CDEPEND}
  27         >=virtual/jre-1.6"
  28
  29 DEPEND="
  30         ${CDEPEND}
  31         >=virtual/jdk-1.6
  32         test? ( dev-java/ant-junit:0 )"
  33
  34 S="${WORKDIR}/${P}-src"
  35
  36 EANT_BUILD_TARGET="compile"
  37 JAVA_ANT_REWRITE_CLASSPATH="yes"
  38 JAVA_ANT_IGNORE_SYSTEM_CLASSES="yes"
  39
  40 java_prepare() {
  41         epatch "${FILESDIR}/${P}-gentoo.patch"
  42         # patch to make the build.xml respect no servletapi
  43         epatch "${FILESDIR}/${P}-servletapi.patch"
  44
  45         # bug #208098
  46         echo "jdk.1.4.present=true" > build.properties
  47
  48         use avalon-framework && echo "avalon-framework.jar=$(java-pkg_getjars avalon-framework-4.2)" >> build.properties
  49         use avalon-logkit && echo "logkit.jar=$(java-pkg_getjars avalon-logkit-2.0)" >> build.properties
  50         use log4j && echo "log4j12.jar=$(java-pkg_getjars log4j)" >> build.properties
  51         use servletapi && echo "servletapi.jar=$(java-pkg_getjar --virtual servlet-api-3.1 servlet-api.jar)" >> build.properties
  52 }
  53
  54 src_install() {
  55         local pkg=org.apache.commons.logging
  56         java-osgi_newjar "target/${P}.jar" "${pkg}" "Apache Commons Logging" "${pkg};version=\"${PV}\", ${pkg}.impl;version=\"${PV}\""
  57         java-pkg_newjar target/${PN}-api-${PV}.jar ${PN}-api.jar
  58         java-pkg_newjar target/${PN}-adapters-${PV}.jar ${PN}-adapters.jar
  59
  60         dodoc RELEASE-NOTES.txt
  61         dohtml PROPOSAL.html
  62         use doc && java-pkg_dojavadoc target/docs/
  63         use source && java-pkg_dosrc src/main/java/org
  64 }
  65
  66 src_test() {
  67         java-pkg-2_src_test
  68 }