dev-java/commons-jexl/commons-jexl-1.1-r1.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 JAVA_PKG_IUSE="doc source test"
   7
   8 inherit java-pkg-2 java-ant-2
   9
  10 DESCRIPTION="Expression language engine, can be embedded in applications and frameworks"
  11 HOMEPAGE="http://commons.apache.org/jexl/"
  12 SRC_URI="mirror://apache/jakarta/commons/jexl/source/${P}-src.tar.gz"
  13
  14 CDEPEND="dev-java/commons-logging
  15                 dev-java/junit:0"
  16
  17 RDEPEND=">=virtual/jre-1.6
  18         ${CDEPEND}"
  19 DEPEND=">=virtual/jdk-1.6
  20         test? ( dev-java/ant-junit )
  21         ${CDEPEND}"
  22
  23 LICENSE="Apache-2.0"
  24 SLOT="1.0"
  25 KEYWORDS="amd64 x86"
  26 IUSE=""
  27
  28 S="${WORKDIR}/${P}-src"
  29
  30 java_prepare() {
  31         # https://issues.apache.org/jira/browse/JEXL-31
  32         epatch "${FILESDIR}/${PV}-test-target.patch"
  33
  34         mkdir -p target/lib && cd target/lib
  35         java-pkg_jar-from junit junit.jar
  36         java-pkg_jar-from commons-logging
  37 }
  38
  39 src_test() {
  40         ANT_TASKS="ant-junit" eant test
  41 }
  42
  43 src_install() {
  44         java-pkg_newjar target/${P}*.jar
  45         dodoc RELEASE-NOTES.txt
  46         use doc && java-pkg_dojavadoc dist/docs/api
  47         use source && java-pkg_dosrc "${S}"/src/java/*
  48 }