dev-java/commons-digester/commons-digester-2.1-r1.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 JAVA_PKG_IUSE="doc examples source test"
   7
   8 inherit eutils java-pkg-2 java-ant-2
   9
  10 MY_P="${P}-src"
  11
  12 DESCRIPTION="Reads XML configuration files to provide initialization of various Java objects"
  13 HOMEPAGE="http://commons.apache.org/digester/"
  14 SRC_URI="mirror://apache/commons/digester/source/${MY_P}.tar.gz"
  15
  16 LICENSE="Apache-2.0"
  17 SLOT="2.1"
  18 KEYWORDS="amd64 ppc64 x86"
  19
  20 CDEPEND="dev-java/commons-beanutils:1.7
  21         >=dev-java/commons-collections-2.1:0
  22         >=dev-java/commons-logging-1.0.2:0"
  23
  24 RDEPEND=">=virtual/jre-1.6
  25         ${CDEPEND}"
  26
  27 DEPEND=">=virtual/jdk-1.6
  28         ${CDEPEND}
  29         test? (
  30                 dev-java/junit:0
  31                 dev-java/ant-junit:0
  32         )"
  33
  34 S="${WORKDIR}/${P}-src"
  35
  36 JAVA_ANT_REWRITE_CLASSPATH="true"
  37 EANT_GENTOO_CLASSPATH="commons-beanutils-1.7,commons-collections,commons-logging"
  38
  39 java_prepare() {
  40         cp "${FILESDIR}"/${P}-build.xml build.xml || die
  41 }
  42
  43 EANT_TEST_GENTOO_CLASSPATH="${EANT_GENTOO_CLASSPATH},junit"
  44
  45 src_test() {
  46         java-pkg-2_src_test
  47 }
  48
  49 src_install() {
  50         java-pkg_newjar target/${PN}.jar
  51
  52         dodoc RELEASE-NOTES.txt
  53
  54         use doc && java-pkg_dojavadoc target/site/apidocs
  55         use source && java-pkg_dosrc src/main/java/org
  56         use examples && java-pkg_doexamples src/examples
  57 }