dev-java/commons-dbutils/commons-dbutils-1.6.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 JAVA_PKG_IUSE="doc source test"
   7
   8 inherit java-pkg-2 java-ant-2
   9
  10 DESCRIPTION="A small set of classes designed to make working with JDBC easier"
  11 HOMEPAGE="http://commons.apache.org/dbutils/"
  12 SRC_URI="mirror://apache/commons/dbutils/source/${P}-src.tar.gz"
  13 LICENSE="Apache-2.0"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~x86"
  16 IUSE=""
  17
  18 DEPEND=">=virtual/jdk-1.6
  19         test? (
  20                 dev-java/mockito:0
  21                 dev-java/ant-junit:0
  22                 dev-java/hamcrest-core:1.3
  23         )"
  24 RDEPEND=">=virtual/jre-1.6"
  25
  26 S="${WORKDIR}/${P}-src"
  27
  28 JAVA_ANT_REWRITE_CLASSPATH="yes"
  29
  30 EANT_TEST_TARGET="test"
  31 EANT_TEST_GENTOO_CLASSPATH="
  32         mockito
  33         hamcrest-core-1.3
  34 "
  35
  36 # Uses a bunch of deprecated methods.
  37 JAVA_RM_FILES=(
  38         src/test/java/org/apache/commons/dbutils/handlers/ArrayHandlerTest.java
  39 )
  40
  41 java_prepare() {
  42         cp "${FILESDIR}"/"${P}-build.xml" build.xml || die
  43 }
  44
  45 src_test() {
  46         java-pkg-2_src_test
  47 }
  48
  49 src_install() {
  50         java-pkg_newjar target/${P}.jar
  51         use doc && java-pkg_dojavadoc target/site/apidocs
  52         use source && java-pkg_dosrc src/main/java
  53 }