dev-java/commons-daemon/commons-daemon-1.1.0.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 JAVA_PKG_IUSE="doc examples source"
   7
   8 inherit autotools java-pkg-2 java-ant-2
   9
  10 DESCRIPTION="Tools to allow Java programs to run as UNIX daemons"
  11 SRC_URI="mirror://apache/commons/daemon/source/${P}-src.tar.gz"
  12 HOMEPAGE="https://commons.apache.org/daemon/"
  13
  14 LICENSE="Apache-2.0"
  15 SLOT="0"
  16 KEYWORDS="~amd64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~x86-solaris"
  17 IUSE="kernel_linux"
  18
  19 CDEPEND="kernel_linux? ( sys-libs/libcap )"
  20
  21 DEPEND="
  22         ${CDEPEND}
  23         >=virtual/jdk-1.6"
  24
  25 RDEPEND="
  26         ${CDEPEND}
  27         >=virtual/jre-1.6"
  28
  29 S="${WORKDIR}/${P}-src"
  30
  31 src_prepare() {
  32         default
  33         cd "${S}/src/native/unix" || die
  34         sed -i "s/powerpc/powerpc|powerpc64/g" support/apsupport.m4 || die
  35         eautoconf
  36 }
  37
  38 src_configure() {
  39         java-ant-2_src_configure
  40         cd "${S}/src/native/unix" || die
  41         default
  42 }
  43
  44 src_compile() {
  45         java-pkg-2_src_compile
  46         cd "${S}/src/native/unix" || die
  47         default
  48 }
  49
  50 src_install() {
  51         dobin src/native/unix/jsvc
  52         java-pkg_newjar dist/*.jar
  53
  54         dodoc README RELEASE-NOTES.txt PROPOSAL.html
  55         use doc && java-pkg_dohtml -r dist/docs/*
  56         use examples && java-pkg_doexamples src/samples
  57         use source && java-pkg_dosrc src/main/java/*
  58 }