dev-java/commons-compress/commons-compress-1.10.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6
   7 JAVA_PKG_IUSE="doc source test"
   8
   9 inherit java-pkg-2 java-ant-2
  10
  11 DESCRIPTION="Java API for working with archive files"
  12 HOMEPAGE="https://commons.apache.org/proper/commons-compress/"
  13 LICENSE="Apache-2.0"
  14 SLOT="0"
  15 KEYWORDS="amd64 x86"
  16 IUSE=""
  17
  18 CDEPEND="dev-java/xz-java:0"
  19
  20 RDEPEND="
  21         ${CDEPEND}
  22         >=virtual/jre-1.6"
  23
  24 DEPEND="
  25         ${CDEPEND}
  26         >=virtual/jdk-1.6
  27         test? (
  28                 dev-java/junit:4
  29                 dev-java/ant-junit:0
  30                 dev-java/hamcrest-core:1.3
  31         )"
  32
  33 S="${WORKDIR}/${P}-src"
  34
  35 JAVA_ANT_BSFIX_EXTRA_ARGS="--maven-cleaning"
  36 EANT_GENTOO_CLASSPATH="xz-java"
  37 EANT_BUILD_TARGET="compile package"
  38 EANT_TEST_GENTOO_CLASSPATH="${EANT_GENTOO_CLASSPATH},junit-4,hamcrest-core-1.3"
  39
  40 # Dubious tests.
  41 JAVA_RM_FILES=(
  42         src/test/java/org/apache/commons/compress/archivers/zip/X5455_ExtendedTimestampTest.java
  43 )
  44
  45 java_prepare() {
  46         cp "${FILESDIR}"/build.xml . || die "Failed to copy build.xml"
  47
  48         # osgi stuff mvn ant:ant doesn't handle
  49         mkdir -p target/osgi || die "Failed to create target dir"
  50         cp "${FILESDIR}"/MANIFEST.MF target/osgi/ || die "Failed to copy manifest"
  51
  52         if ! use test; then
  53                 find -name "*.jar" -delete || die "Failed to remove test resources"
  54         fi
  55 }
  56
  57 src_test() {
  58         EANT_TEST_TARGET="compile-tests test" \
  59                 java-pkg-2_src_test
  60 }
  61
  62 src_install() {
  63         java-pkg_newjar "target/${PN}-1.1.jar"
  64         use doc && java-pkg_dojavadoc target/site/apidocs
  65         use source && java-pkg_dosrc src/main/java/*
  66 }