dev-java/bcel/bcel-6.0_rc3.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 MY_PV="${PV//./_}"
   7 MY_PV="${MY_PV/rc/RC}"
   8 MY_P="BCEL_${MY_PV}"
   9
  10 JAVA_PKG_IUSE="doc source"
  11
  12 inherit java-pkg-2 java-pkg-simple
  13
  14 DESCRIPTION="The Byte Code Engineering Library: analyze, create, manipulate Java class files"
  15 HOMEPAGE="http://commons.apache.org/bcel/"
  16 SRC_URI="https://github.com/apache/commons-${PN}/archive/${MY_P}.tar.gz"
  17
  18 LICENSE="Apache-2.0"
  19 SLOT="0"
  20 KEYWORDS="amd64 ~arm arm64 ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  21 IUSE="test"
  22 RESTRICT="!test? ( test )"
  23
  24 RDEPEND=">=virtual/jre-1.5"
  25 DEPEND=">=virtual/jdk-1.5
  26         test? ( dev-java/junit:4 )"
  27
  28 S="${WORKDIR}/commons-${PN}-${MY_P}/src"
  29 JAVA_SRC_DIR="main/java"
  30
  31 src_install() {
  32         java-pkg-simple_src_install
  33         dodoc ../{NOTICE,README,RELEASE-NOTES}.txt
  34 }
  35
  36 src_test() {
  37         cd test/java || die
  38
  39         local CP=".:${S}/${PN}.jar:$(java-pkg_getjars junit-4)"
  40         local TESTS=$(find * -name "*TestCase.java" ! -name "Abstract*")
  41         TESTS="${TESTS//.java}"
  42         TESTS="${TESTS//\//.}"
  43
  44         ejavac -g -cp "${CP}" -d . $(find * -name "*.java")
  45         ejunit4 -classpath "${CP}" ${TESTS}
  46 }