dev-java/antlr/antlr-4.5.1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 JAVA_PKG_IUSE="source"
   7
   8 inherit java-pkg-2 java-pkg-simple
   9
  10 DESCRIPTION="A parser generator for many languages"
  11 HOMEPAGE="https://www.antlr.org/"
  12 SRC_URI="https://github.com/${PN}/${PN}4/archive/${PV}.tar.gz -> ${P}.tar.gz
  13         https://www.antlr.org/download/${P}-complete.jar" # Prebuilt version needed.
  14 LICENSE="BSD"
  15 SLOT="4"
  16 KEYWORDS="amd64 ~arm ppc64 x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  17 IUSE="doc test"
  18 RESTRICT="!test? ( test )"
  19
  20 CDEPEND="dev-java/antlr:3.5
  21         dev-java/stringtemplate:4
  22         dev-java/treelayout:0"
  23
  24 RDEPEND="${CDEPEND}
  25         >=virtual/jre-1.6"
  26
  27 DEPEND="${CDEPEND}
  28         >=virtual/jdk-1.6
  29         test? (
  30                 dev-java/hamcrest-core:1.3
  31                 dev-java/junit:4
  32         )"
  33
  34 S="${WORKDIR}/${PN}4-${PV}"
  35 JAVA_GENTOO_CLASSPATH="stringtemplate-4,treelayout"
  36
  37 src_unpack() {
  38         unpack ${P}.tar.gz
  39 }
  40
  41 java_prepare() {
  42         java-pkg_clean
  43 }
  44
  45 src_configure() {
  46         # TODO: Make java-config accept a jar@package query.
  47         JAVA_GENTOO_CLASSPATH_EXTRA="${S}/${PN}-runtime.jar:$(java-pkg_getjar antlr-3.5 antlr-runtime.jar)"
  48 }
  49
  50 src_compile() {
  51         cd "${S}/runtime/Java/src"
  52         local G PKG
  53
  54         for G in $(find * -name "*.g4"); do
  55                 PKG="${G%/*}"
  56                 PKG="${PKG//\//.}"
  57                 java -jar "${DISTDIR}/${P}-complete.jar" -package "${PKG}" "${G}" || die
  58         done
  59
  60         JAVA_JAR_FILENAME="${S}/${PN}-runtime.jar" JAVA_PKG_IUSE="doc" java-pkg-simple_src_compile
  61
  62         cd "${S}/tool/src"
  63         antlr3.5 $(find -name "*.g") || die
  64         JAVA_JAR_FILENAME="${S}/${PN}-tool.jar" java-pkg-simple_src_compile
  65         java-pkg_addres "${S}/${PN}-tool.jar" ../resources
  66 }
  67
  68 src_install() {
  69         java-pkg_dojar ${PN}-{runtime,tool}.jar
  70         java-pkg_dolauncher ${PN}${SLOT} --main org.antlr.v4.Tool
  71         use doc && java-pkg_dojavadoc runtime/Java/src/target/api
  72         use source && java-pkg_dosrc runtime/Java/src/org tool/src/org
  73 }
  74
  75 junit_suite() {
  76         cd "${S}/$1-testsuite/test" || die
  77         local CP=".:${S}/runtime-testsuite/test:${S}/${PN}-tool.jar:$(java-pkg_getjars hamcrest-core-1.3,junit-4,${JAVA_GENTOO_CLASSPATH}):${JAVA_GENTOO_CLASSPATH_EXTRA}"
  78
  79         local TESTS=$(find ${2:-*} -name "Test*.java")
  80         TESTS="${TESTS//.java}"
  81         TESTS="${TESTS//\//.}"
  82
  83         ejavac -classpath "${CP}" $(find ${2:-*} -name "*.java")
  84         ejunit4 -classpath "${CP}" ${TESTS}
  85 }
  86
  87 src_test() {
  88         # Only run Java runtime tests as we haven't built other languages.
  89         junit_suite runtime org/antlr/v4/test/runtime/java
  90         junit_suite tool
  91 }