dev-java/antlr/antlr-2.7.7-r8.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 JAVA_PKG_IUSE="doc source"
   7
   8 inherit java-pkg-2 java-pkg-simple
   9
  10 DESCRIPTION="A parser generator for many languages"
  11 HOMEPAGE="https://www.antlr2.org/"
  12 SRC_URI="https://www.antlr2.org/download/${P}.tar.gz"
  13 LICENSE="public-domain"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~arm ~arm64 ~ppc64 ~x86 ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~sparc-solaris ~sparc64-solaris ~x64-solaris ~x86-solaris"
  16 IUSE="examples"
  17
  18 RDEPEND=">=virtual/jre-1.6"
  19 DEPEND=">=virtual/jdk-1.6"
  20
  21 S="${WORKDIR}/${P}"
  22
  23 JAVA_SRC_DIR="${S}/${PN}"
  24
  25 DOCS=( CHANGES.txt README.txt )
  26
  27 src_prepare() {
  28         default
  29         java-pkg_clean
  30
  31         # Delete build files from examples.
  32         find examples \( -name Makefile.in -o -name shiplist \) -delete || die
  33 }
  34
  35 # Avoid configure script.
  36 src_configure() { :; }
  37
  38 src_install() {
  39         java-pkg-simple_src_install
  40         java-pkg_dolauncher antlr --main antlr.Tool
  41
  42         use doc && java-pkg_dohtml -r doc/*
  43         use examples && java-pkg_doexamples examples/java
  44         use source && java-pkg_dosrc antlr
  45
  46         einstalldocs
  47 }