dev-java/ant-ivy/ant-ivy-2.3.0-r2.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5
   6 JAVA_PKG_IUSE="doc examples source test"
   7
   8 # Register this as a split-ant task.
   9 WANT_SPLIT_ANT="true"
  10
  11 # Don't rewrite examples, that's bad.
  12 JAVA_PKG_BSFIX_ALL="no"
  13
  14 inherit java-pkg-2 java-ant-2 eutils
  15
  16 MY_PN="apache-ivy"
  17 MY_P="${MY_PN}-${PV}"
  18
  19 DESCRIPTION="Ivy is a free java based dependency manager"
  20 HOMEPAGE="https://ant.apache.org/ivy/"
  21 SRC_URI="mirror://apache/ant/ivy/${PV}/${MY_P}-src.tar.gz"
  22
  23 LICENSE="Apache-2.0"
  24 SLOT="2"
  25 KEYWORDS="amd64 ppc64 x86 ~amd64-linux ~x86-linux ~x86-macos"
  26
  27 # We cannot build tests yet as there is no org.apache.tools.ant.BuildFileTest packaged anywhere yet.
  28 RESTRICT="test"
  29
  30 # SLOT to use for all bc dependencies.
  31 BC_SLOT="1.50"
  32
  33 # There may be additional optional dependencies (commons-logging, commons-lang...)
  34 CDEPEND="dev-java/jsch:0
  35         dev-java/bcpg:${BC_SLOT}
  36         dev-java/ant-core:0
  37         dev-java/bcpkix:${BC_SLOT}
  38         dev-java/bcprov:${BC_SLOT}
  39         dev-java/commons-vfs:0
  40         dev-java/jakarta-oro:2.0
  41         dev-java/commons-httpclient:3"
  42
  43 DEPEND=">=virtual/jdk-1.6
  44         test? (
  45                 dev-java/ant-junit:0
  46         )
  47         ${CDEPEND}"
  48
  49 RDEPEND=">=virtual/jre-1.6
  50         ${CDEPEND}"
  51
  52 S="${WORKDIR}/${MY_P}"
  53
  54 java_prepare() {
  55         # This stuff needs removing.
  56         local CLEANUP=(
  57                 doc/reports
  58                 test/triggers
  59                 doc/configuration
  60                 test/repositories
  61                 test/java/org/apache/ivy/core/settings/custom-resolver.jar
  62                 src/example/chained-resolvers/settings/repository/test-1.0.jar
  63         )
  64
  65         rm -rf "${CLEANUP[@]}" || die
  66
  67         java-ant_rewrite-classpath
  68         mkdir lib || die
  69 }
  70
  71 JAVA_ANT_REWRITE_CLASSPATH="true"
  72
  73 EANT_GENTOO_CLASSPATH="
  74         jsch
  75         bcpkix-${BC_SLOT}
  76         ant-core
  77         bcpg-${BC_SLOT}
  78         commons-vfs
  79         bcprov-${BC_SLOT}
  80         jakarta-oro-2.0
  81         commons-httpclient-3
  82 "
  83
  84 EANT_BUILD_TARGET="/offline jar"
  85
  86 EANT_EXTRA_ARGS="-Dbuild.version=${PV} -Dbundle.version=${PV}"
  87
  88 src_test() {
  89         java-pkg_jar-from --into lib junit
  90         ANT_TASKS="ant-junit" eant "/offline test"
  91 }
  92
  93 src_install() {
  94         java-pkg_dojar build/artifact/jars/ivy.jar
  95         java-pkg_register-ant-task
  96
  97         if use doc; then
  98                 java-pkg_dojavadoc build/doc/reports/api
  99                 java-pkg_dohtml -r doc
 100         fi
 101
 102         use examples && java-pkg_doexamples src/example
 103         use source && java-pkg_dosrc src/java/*
 104 }