dev-java/annogen/annogen-0.1.0-r3.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="5"
   5 JAVA_PKG_IUSE="doc source"
   6
   7 inherit java-pkg-2 java-pkg-simple
   8
   9 DESCRIPTION="A tool which helps you work with JSR175 annotations"
  10 HOMEPAGE="https://github.com/codehaus/annogen"
  11 SRC_URI="http://dist.codehaus.org/${PN}/distributions/${P}.zip"
  12
  13 LICENSE="BSD"
  14 SLOT="0"
  15 KEYWORDS="amd64 ~ppc64 ~x86"
  16
  17 CDEPEND="
  18         dev-java/qdox:1.6
  19         dev-java/ant-core:0"
  20
  21 RDEPEND="
  22         ${CDEPEND}
  23         >=virtual/jre-1.6"
  24
  25 DEPEND="
  26         ${CDEPEND}
  27         >=virtual/jdk-1.6"
  28
  29 # com.sun.mirror.declaration was removed from JDK 7 onwards.
  30 # These two files are just interfaces anyway.
  31 JAVA_RM_FILES=(
  32         org/codehaus/annogen/view/MirrorAnnoViewer.java
  33         org/codehaus/annogen/override/MirrorElementIdPool.java
  34 )
  35
  36 JAVA_GENTOO_CLASSPATH="
  37         ant-core
  38         qdox-1.6
  39 "
  40
  41 src_unpack() {
  42         default
  43         unzip -o -q "${S}/${PN}-src-${PV}.zip" || die
  44 }
  45
  46 java_prepare() {
  47         java-pkg_clean
  48         rm -rv examples || die
  49 }
  50
  51 src_compile() {
  52         # Needed for com.sun.* imports
  53         JAVA_GENTOO_CLASSPATH_EXTRA="$(java-config -t)" \
  54                 java-pkg-simple_src_compile
  55 }