dev-haskell/bio/bio-0.5.3-r2.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 # ebuild generated by hackport 0.3.2.9999
   7
   8 CABAL_FEATURES="bin lib profile haddock hoogle hscolour"
   9 inherit eutils haskell-cabal
  10
  11 DESCRIPTION="A bioinformatics library"
  12 HOMEPAGE="http://biohaskell.org/Libraries/Bio"
  13 SRC_URI="https://hackage.haskell.org/package/${P}/${P}.tar.gz"
  14
  15 LICENSE="LGPL-2.1"
  16 SLOT="0/${PV}"
  17 KEYWORDS="~amd64 ~x86"
  18 IUSE="+examples test"
  19 RESTRICT="!test? ( test )"
  20
  21 RDEPEND=">=dev-haskell/binary-0.4:=[profile?]
  22                 dev-haskell/mtl:=[profile?]
  23                 dev-haskell/old-time:=[profile?]
  24                 dev-haskell/parallel:=[profile?]
  25                 dev-haskell/parsec:=[profile?]
  26                 >=dev-haskell/quickcheck-2:2=[profile?]
  27                 dev-haskell/random:=[profile?]
  28                 >=dev-haskell/tagsoup-0.8:=[profile?]
  29                 >=dev-lang/ghc-6.10.4:="
  30 DEPEND="${RDEPEND}
  31                 >=dev-haskell/cabal-1.6"
  32
  33 src_prepare() {
  34         epatch "${FILESDIR}"/${P}-ghc-7.10.patch
  35
  36         cabal_chdeps \
  37                 'binary >=0.4 && <0.5' 'binary >=0.4'
  38 }
  39
  40 src_configure() {
  41         haskell-cabal_src_configure \
  42                 $(cabal_flag examples examples) \
  43                 $(cabal_flag test test)
  44 }
  45
  46 src_test() {
  47         dist/build/qc/qc || die
  48 }
  49
  50 src_install() {
  51         haskell-cabal_src_install
  52
  53         use test && rm "${ED}"/usr/bin/qc
  54         # many examples collide with dev-haskell/flower
  55         if use examples ; then
  56                 pushd "${ED}"/usr/bin
  57                 local example
  58                 for example in *
  59                 do
  60                         mv "${example}" "${PN}-example-${example}"
  61                 done
  62                 popd
  63         fi
  64 }