dev-go/go-oauth2/go-oauth2-0_pre20160222.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit eutils golang-base
   7
   8 MY_PN=${PN##*-}
   9 EGO_PN="golang.org/x/${MY_PN}/..."
  10 EGIT_COMMIT="2cd4472c321b6cba78e029d99f0e7fe51032fd21"
  11
  12 HOMEPAGE="https://godoc.org/${EGO_PN%/*}"
  13 DESCRIPTION="Go client implementation for OAuth 2.0 spec"
  14 SRC_URI="
  15         https://github.com/golang/${MY_PN}/archive/${EGIT_COMMIT}.tar.gz -> ${P}.tar.gz
  16         https://github.com/golang/net/archive/b6d7b1396ec874c3b00f6c84cd4301a17c56c8ed.tar.gz -> go-net-0_pre20160216.tar.gz
  17         https://github.com/GoogleCloudPlatform/gcloud-golang/archive/872c736f496c2ba12786bedbb8325576bbdb33cf.tar.gz -> gcloud-golang-872c736f496c2ba12786bedbb8325576bbdb33cf.tar.gz"
  18
  19 SLOT="0/${PVR}"
  20 LICENSE="BSD"
  21 KEYWORDS="~amd64"
  22 IUSE=""
  23
  24 DEPEND="dev-go/go-tools"
  25 RDEPEND=""
  26
  27 EGIT_CHECKOUT_DIR="${S}"
  28 STRIP_MASK="*.a"
  29
  30 get_archive_go_package() {
  31         local archive=${1} uri x
  32         case ${archive} in
  33                 ${PN}-*) echo "oauth2-* golang.org/x/oauth2"; return;;
  34                 gcloud-golang-*) echo "gcloud-golang-* google.golang.org/cloud"; return;;
  35                 go-net-*) echo "net-* golang.org/x/net"; return;;
  36         esac
  37         for x in ${SRC_URI}; do
  38                 if [[ ${x} == http* ]]; then
  39                         uri=${x}
  40                 elif [[ ${x} == ${archive} ]]; then
  41                         break
  42                 fi
  43         done
  44         uri=${uri#https://}
  45         uri=${uri%/archive/*}
  46         echo "${uri##*/}-* ${uri}"
  47 }
  48
  49 unpack_go_packages() {
  50         local go_package pattern x
  51         # Unpack packages to appropriate locations for GOPATH
  52         for x in ${A}; do
  53                 unpack ${x}
  54                 if [[ ${x} == *.tar.gz ]]; then
  55                         go_package=$(get_archive_go_package ${x})
  56                         pattern=${go_package%% *}
  57                         go_package=${go_package##* }
  58                         if [[ ${x%.tar.gz} -ef ${S} ]]; then
  59                                 mv "${S}"{,_} || die
  60                                 mkdir -p "${S}/src/${go_package%/*}" || die
  61                                 mv "${S}"_ "${S}/src/${go_package}" || die || die
  62                         else
  63                                 mkdir -p "${S}/src/${go_package%/*}" || die
  64                                 for x in ${pattern}; do
  65                                         if [[ ! ${x} -ef ${S} ]]; then
  66                                                 mv "${x}" "${S}/src/${go_package}" || die
  67                                         fi
  68                                 done
  69                         fi
  70                 fi
  71         done
  72 }
  73
  74 src_unpack() {
  75         unpack_go_packages
  76
  77         # Create a writable GOROOT in order to avoid sandbox violations.
  78         # Omit $(get_golibdir_gopath) from GOPATH, in order to avoid
  79         # more sandbox violations (bug 575722).
  80         GOROOT="${WORKDIR}/goroot" GOPATH="${S}"
  81         cp -sR "$(go env GOROOT)" "${GOROOT}" || die
  82         rm -rf "${GOROOT}/src/${EGO_PN%/*}" || die
  83         export GOROOT GOPATH
  84
  85         mkdir -p "${GOROOT}/src/google.golang.org" || die
  86         rm -rf "${GOROOT}/src/google.golang.org"/* || die
  87         rm -rf "${GOROOT}/pkg/${KERNEL}_${ARCH}/google.golang.org" || die
  88 }
  89
  90 src_compile() {
  91         GOROOT="${GOROOT}" GOPATH="${GOPATH}" \
  92                 go install -v -work -x ${EGO_BUILD_FLAGS} "${EGO_PN}" || die
  93 }
  94
  95 src_test() {
  96         # google/example_test.go imports appengine, introducing a circular dep
  97         mv src/${EGO_PN%/*}/google/example_test.go{,_} || die
  98         go test -x -v "${EGO_PN}" || die $?
  99         mv src/${EGO_PN%/*}/google/example_test.go{_,} || die
 100 }
 101
 102 src_install() {
 103         golang_install_pkgs
 104 }
 105
 106 golang_install_pkgs() {
 107         insinto $(dirname "${EPREFIX}$(get_golibdir)/src/${EGO_PN%/*}")
 108         rm -rf "${S}"/src/${EGO_PN%/*}/.git*
 109         doins -r "${S}"/src/${EGO_PN%/*}
 110         insinto $(dirname "${EPREFIX}$(get_golibdir)/pkg/$(go env GOOS)_$(go env GOARCH)/${EGO_PN%/*}")
 111         doins -r "${S}"/pkg/$(go env GOOS)_$(go env GOARCH)/${EGO_PN%/*}{,.a}
 112 }