dev-games/ode/ode-0.14-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 inherit autotools eutils
   7
   8 DESCRIPTION="Open Dynamics Engine SDK"
   9 HOMEPAGE="http://ode.org/"
  10 SRC_URI="https://bitbucket.org/odedevs/ode/downloads/${P}.tar.gz"
  11
  12 LICENSE="|| ( LGPL-2.1+ BSD )"
  13 SLOT="0/6"
  14 KEYWORDS="~amd64 ~ppc ~ppc64 ~sparc ~x86 ~x86-fbsd ~amd64-linux ~x86-linux"
  15 IUSE="debug doc double-precision examples gyroscopic static-libs"
  16
  17 RDEPEND="examples? (
  18         virtual/glu
  19         virtual/opengl )"
  20 DEPEND="${RDEPEND}
  21         doc? ( app-doc/doxygen )"
  22
  23 MY_EXAMPLES_DIR=/usr/share/doc/${PF}/examples
  24
  25 src_prepare() {
  26         sed -i \
  27                 -e "s:\$.*/drawstuff/textures:${MY_EXAMPLES_DIR}:" \
  28                 drawstuff/src/Makefile.am \
  29                 ode/demo/Makefile.am || die
  30         eautoreconf
  31 }
  32
  33 src_configure() {
  34         # use bash (bug #335760)
  35         CONFIG_SHELL=/bin/bash \
  36         econf \
  37                 --enable-shared \
  38                 $(use_enable static-libs static) \
  39                 $(use_enable debug asserts) \
  40                 $(use_enable double-precision) \
  41                 $(use_enable examples demos) \
  42                 $(use_enable gyroscopic) \
  43                 $(use_with examples drawstuff X11)
  44 }
  45
  46 src_compile() {
  47         emake
  48         if use doc ; then
  49                 cd ode/doc
  50                 doxygen Doxyfile || die
  51         fi
  52 }
  53
  54 src_install() {
  55         DOCS="CHANGELOG.txt README.md" \
  56                 default
  57         prune_libtool_files
  58         if use doc ; then
  59                 dohtml docs/*
  60         fi
  61         if use examples; then
  62                 docompress -x "${MY_EXAMPLES_DIR}"
  63                 insinto "${MY_EXAMPLES_DIR}"
  64                 exeinto "${MY_EXAMPLES_DIR}"
  65                 doexe drawstuff/dstest/dstest
  66                 doins ode/demo/*.{c,cpp,h} \
  67                         drawstuff/textures/*.ppm \
  68                         drawstuff/dstest/dstest.cpp \
  69                         drawstuff/src/{drawstuff.cpp,internal.h,x11.cpp}
  70                 cd ode/demo
  71                 local f
  72                 for f in *.c* ; do
  73                         doexe .libs/${f%.*}
  74                 done
  75         fi
  76 }