dev-games/freecell-solver/freecell-solver-5.22.1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 PYTHON_COMPAT=( python3_{6,7,8} )
   7 inherit cmake python-single-r1
   8
   9 DESCRIPTION="C library for automatically solving Freecell and some other solitaire variants"
  10 HOMEPAGE="https://fc-solve.shlomifish.org/"
  11 SRC_URI="https://fc-solve.shlomifish.org/downloads/fc-solve/${P}.tar.xz"
  12
  13 LICENSE="MIT"
  14 SLOT="0"
  15 KEYWORDS="amd64 arm64 x86"
  16 IUSE="tcmalloc"
  17
  18 REQUIRED_USE="${PYTHON_REQUIRED_USE}"
  19
  20 RDEPEND="${PYTHON_DEPS}
  21         $(python_gen_cond_dep '
  22                 dev-python/pysol_cards[${PYTHON_MULTI_USEDEP}]
  23                 dev-python/random2[${PYTHON_MULTI_USEDEP}]
  24                 dev-python/six[${PYTHON_MULTI_USEDEP}]
  25         ')
  26         tcmalloc? ( dev-util/google-perftools )
  27 "
  28 DEPEND="${RDEPEND}
  29         dev-perl/Path-Tiny
  30         dev-perl/Template-Toolkit
  31 "
  32
  33 DOCS=( README.html )
  34
  35 PATCHES=( "${FILESDIR}/${P}-no-docs.patch" )
  36
  37 src_prepare() {
  38         python_fix_shebang board_gen
  39         cmake_src_prepare
  40 }
  41
  42 src_configure() {
  43         local mycmakeargs=(
  44                 -DBUILD_STATIC_LIBRARY=OFF
  45                 -DFCS_BUILD_DOCS=OFF
  46                 -DFCS_WITH_TEST_SUITE=OFF #requires unpackaged dependencies
  47                 -DFCS_AVOID_TCMALLOC=$(usex !tcmalloc)
  48         )
  49
  50         cmake_src_configure
  51 }