dev-embedded/libftdi/libftdi-0.19.ebuild

   1 # Copyright 1999-2011 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="2"
   6
   7 if [[ ${PV} == 9999* ]] ; then
   8         EGIT_REPO_URI="git://developer.intra2net.com/${PN}"
   9         inherit git-2 autotools
  10 else
  11         SRC_URI="http://www.intra2net.com/en/developer/${PN}/download/${P}.tar.gz"
  12         KEYWORDS="amd64 arm ppc ppc64 sparc x86"
  13 fi
  14
  15 DESCRIPTION="Userspace access to FTDI USB interface chips"
  16 HOMEPAGE="http://www.intra2net.com/en/developer/libftdi/"
  17
  18 LICENSE="LGPL-2"
  19 SLOT="0"
  20 IUSE="cxx doc examples python static-libs"
  21
  22 RDEPEND="virtual/libusb:0
  23         cxx? ( dev-libs/boost )
  24         python? ( dev-lang/python )"
  25 DEPEND="${RDEPEND}
  26         python? ( dev-lang/swig )
  27         doc? ( app-doc/doxygen )"
  28
  29 src_prepare() {
  30         if [[ ${PV} == 9999* ]] ; then
  31                 mkdir -p m4
  32                 eautoreconf
  33         fi
  34 }
  35
  36 src_configure() {
  37         econf \
  38                 $(use_enable cxx libftdipp) \
  39                 $(use_with doc docs) \
  40                 $(use_with examples) \
  41                 $(use_enable python python-binding) \
  42                 $(use_enable static-libs static)
  43 }
  44
  45 src_install() {
  46         emake DESTDIR="${D}" install || die
  47         use static-libs || find "${D}" -name '*.la' -delete
  48         dodoc ChangeLog README
  49
  50         if use doc ; then
  51                 doman doc/man/man3/*
  52                 dohtml doc/html/*
  53         fi
  54         if use examples ; then
  55                 docinto examples
  56                 dodoc examples/*.c
  57         fi
  58 }