dev-embedded/gpsim/gpsim-0.30.0.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit ltprune
   6
   7 DESCRIPTION="A simulator for the Microchip PIC microcontrollers"
   8 HOMEPAGE="http://gpsim.sourceforge.net"
   9 SRC_URI="mirror://sourceforge/${PN}/${P}.tar.gz"
  10
  11 LICENSE="GPL-2"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~ppc ~ppc64 ~x86"
  14 IUSE="doc gtk static-libs"
  15
  16 RDEPEND=">=dev-embedded/gputils-0.12
  17         dev-libs/glib:2
  18         dev-libs/popt
  19         sys-libs/readline:0=
  20         gtk? ( >=x11-libs/gtk+extra-2 )"
  21 DEPEND="${RDEPEND}
  22         sys-devel/flex
  23         virtual/pkgconfig
  24         virtual/yacc"
  25
  26 DOCS=( ANNOUNCE AUTHORS ChangeLog HISTORY PROCESSORS README README.MODULES TODO )
  27
  28 src_configure() {
  29         econf \
  30                 $(use_enable gtk gui) \
  31                 $(use_enable static-libs static)
  32 }
  33
  34 src_install() {
  35         default
  36         use doc && dodoc doc/gpsim.pdf
  37         prune_libtool_files
  38 }