dev-dotnet/log4net/log4net-1.2.11.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI="4"
   6
   7 inherit eutils mono multilib versionator
   8
   9 PV_MAJOR=$(get_version_component_range 1-2)
  10
  11 DESCRIPTION="tool to help the programmer output log statements to a variety of output targets"
  12 HOMEPAGE="http://logging.apache.org/log4net/"
  13 SRC_URI="mirror://apache/logging/log4net/source/${P}-src.zip
  14         https://dev.gentoo.org/~pacho/dotnet/log4net.snk"
  15
  16 LICENSE="Apache-2.0"
  17 SLOT="0"
  18 KEYWORDS="amd64 x86"
  19 IUSE=""
  20
  21 RDEPEND=">=dev-lang/mono-2.0"
  22 DEPEND="${RDEPEND}"
  23
  24 src_compile() {
  25         /usr/bin/mcs \
  26                 -t:library \
  27                 -out:log4net.dll \
  28                 -keyfile:"${DISTDIR}"/log4net.snk \
  29                 -r:System.Data \
  30                 -r:System.Web \
  31                 $(find src -name "*.cs") || die
  32 }
  33
  34 src_install() {
  35         egacinstall log4net.dll
  36         dodir /usr/$(get_libdir)/pkgconfig
  37         sed -e "s:@VERSION@:${PV}:" \
  38                 -e "s:@LIBDIR@:$(get_libdir):" \
  39                 -e "s:@NET_VERSION@:2.0:" \
  40                 "${FILESDIR}"/${PN}.pc.in-r1 > "${D}"/usr/$(get_libdir)/pkgconfig/${PN}-${PV}.pc
  41         dosym ${PN}-${PV}.pc /usr/$(get_libdir)/pkgconfig/${PN}-${PV_MAJOR}.pc
  42         dosym ${PN}-${PV}.pc /usr/$(get_libdir)/pkgconfig/${PN}.pc
  43
  44         dodoc README.txt STATUS.txt
  45 }