dev-db/percona-toolkit/percona-toolkit-3.0.13.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 inherit perl-module
   7
   8 DESCRIPTION="Advanced command-line tools to perform a variety of MySQL and system tasks"
   9 HOMEPAGE="https://www.percona.com/software/mysql-tools/percona-toolkit"
  10 SRC_URI="https://www.percona.com/downloads/${PN}/${PV}/source/tarball/${P}.tar.gz"
  11
  12 LICENSE="|| ( GPL-2 Artistic )"
  13 SLOT="0"
  14 KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux"
  15 # Package warrants IUSE doc
  16 IUSE=""
  17
  18 COMMON_DEPEND="dev-perl/DBI
  19         dev-perl/DBD-mysql
  20         virtual/perl-Time-HiRes"
  21 RDEPEND="${COMMON_DEPEND}
  22         dev-perl/JSON
  23         dev-perl/libwww-perl
  24         dev-perl/Role-Tiny
  25         virtual/perl-File-Path
  26         virtual/perl-Getopt-Long
  27         virtual/perl-Time-Local
  28         virtual/perl-Digest-MD5
  29         virtual/perl-IO-Compress
  30         virtual/perl-File-Temp
  31         virtual/perl-File-Spec
  32         virtual/perl-Scalar-List-Utils
  33         dev-perl/TermReadKey"
  34 DEPEND="${COMMON_DEPEND}
  35         virtual/perl-ExtUtils-MakeMaker"
  36
  37 # Bug #501904 - CVE-2014-2029
  38 # sed -i -e '/^=item --\[no\]version-check/,/^default: yes/{/^default: yes/d}' bin/*
  39 # ^ is *-no-versioncheck.patch
  40 PATCHES=(
  41         "${FILESDIR}"/${PN}-3.0.7-no-versioncheck.patch
  42         "${FILESDIR}"/${PN}-3.0.10-slave-delay-fix.patch
  43 )
  44
  45 src_prepare() {
  46         default
  47
  48         sed -i \
  49                 -e "s/=> 'percona-toolkit',/=> 'Percona::Toolkit',/g" \
  50                 Makefile.PL || die
  51 }