dev-db/oracle-instantclient-jdbc/oracle-instantclient-jdbc-11.2.0.3.ebuild

   1 # Copyright 1999-2012 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="4"
   5
   6 inherit eutils multilib
   7
   8 MY_PLAT_x86="Linux x86"
   9 MY_A_x86="${PN/oracle-/}-linux-${PV}.0.zip"
  10
  11 MY_PLAT_amd64="Linux x86-64"
  12 MY_A_amd64="${PN/oracle-/}-linux.x64-${PV}.0.zip"
  13
  14 DESCRIPTION="Oracle 11g Instant Client: JDBC supplement"
  15 HOMEPAGE="http://www.oracle.com/technetwork/database/features/instant-client/index.html"
  16 SRC_URI="
  17         x86?   ( ${MY_A_x86}                             )
  18         amd64? ( ${MY_A_amd64} multilib? ( ${MY_A_x86} ) )
  19 "
  20
  21 LICENSE="OTN"
  22 SLOT="0"
  23 KEYWORDS="amd64 x86"
  24 RESTRICT="fetch"
  25 IUSE="multilib"
  26
  27 DEPEND="app-arch/unzip"
  28 RDEPEND="~dev-db/oracle-instantclient-basic-${PV}"
  29
  30 S="${WORKDIR}"
  31
  32 QA_PREBUILT="usr/lib*/oracle/${PV}/client/lib*/lib*"
  33
  34 default_abi() {
  35         [[ ${DEFAULT_ABI} == 'default' ]] && echo ${ARCH} || echo ${DEFAULT_ABI}
  36 }
  37
  38 abi_list() {
  39         if use multilib; then
  40                 echo ${MULTILIB_ABIS}
  41         else
  42                 default_abi
  43         fi
  44         return 0
  45 }
  46
  47 set_abivars() {
  48         local abi=$1
  49         # platform name
  50         MY_PLAT=MY_PLAT_${abi}
  51         MY_PLAT=${!MY_PLAT}
  52         # runtime distfile
  53         MY_A=MY_A_${abi}
  54         MY_A=${!MY_A}
  55         # abi sourcedir
  56         MY_S="${S}/${abi}/instantclient_11_2"
  57         # ABI might not need to be set at all
  58         [[ -n ${ABI} ]] && MY_ABI=${abi} || MY_ABI=
  59         # abi libdir
  60         MY_LIBDIR=$(ABI=${MY_ABI} get_libdir)
  61 }
  62
  63 pkg_nofetch() {
  64         eerror "Please go to"
  65         eerror "  ${HOMEPAGE%/*}/index-097480.html"
  66         eerror "  and download"
  67         local abi
  68         for abi in $(abi_list)
  69         do
  70                 set_abivars ${abi}
  71                 eerror "Instant Client for ${MY_PLAT}"
  72                 eerror "    JDBC: ${MY_A}"
  73         done
  74         eerror "After downloading, put them in:"
  75         eerror "    ${DISTDIR}/"
  76 }
  77
  78 src_unpack() {
  79         local abi
  80         for abi in $(abi_list)
  81         do
  82                 set_abivars ${abi}
  83                 mkdir -p "${MY_S%/*}" || die
  84                 cd "${MY_S%/*}" || die
  85                 unpack ${MY_A}
  86         done
  87 }
  88
  89 src_install() {
  90         # all binaries go here
  91         local oracle_home=/usr/$(get_libdir)/oracle/${PV}/client
  92         into "${oracle_home}"
  93
  94         local abi
  95         for abi in $(abi_list)
  96         do
  97                 set_abivars ${abi}
  98                 einfo "Installing runtime for ${MY_PLAT} ..."
  99
 100                 cd "${MY_S}" || die
 101
 102                 ABI=${MY_ABI} dolib.so lib*$(get_libname)*
 103
 104                 insinto "${oracle_home}"/${MY_LIBDIR}
 105                 doins *.jar
 106
 107                 eend $?
 108         done
 109 }