dev-db/mysql-connector-c++/mysql-connector-c++-1.1.8.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit cmake-utils flag-o-matic
   7
   8 DESCRIPTION="MySQL database connector for C++ (mimics JDBC 4.0 API)"
   9 HOMEPAGE="http://dev.mysql.com/downloads/connector/cpp/"
  10 URI_DIR="Connector-C++"
  11 SRC_URI="https://dev.mysql.com/get/Downloads/${URI_DIR}/${P}.tar.gz"
  12
  13 LICENSE="GPL-2"
  14 SLOT="0"
  15 KEYWORDS="~amd64 ~arm ~ppc ~ppc64 ~sparc ~x86"
  16 IUSE="debug examples gcov static-libs"
  17
  18 DEPEND="virtual/libmysqlclient:=
  19         dev-libs/boost:=
  20         dev-libs/openssl:0=
  21         !<dev-db/mysql-connector-c-6.1.8"
  22 RDEPEND="${DEPEND}"
  23
  24 PATCHES=(
  25         "${FILESDIR}/${PN}-1.1.6-fix-cmake.patch"
  26         "${FILESDIR}/${PN}-1.1.8-fix-mariadb.patch"
  27 )
  28
  29 src_configure() {
  30         # native lib/wrapper needs this!
  31         append-flags "-fno-strict-aliasing"
  32
  33         local mycmakeargs=(
  34                 -DMYSQLCPPCONN_BUILD_EXAMPLES=OFF
  35                 -DMYSQLCPPCONN_ICU_ENABLE=OFF
  36                 -DUSE_MYSQLCPPCONN_TRACE_ENABLE=$(usex debug ON OFF)
  37                 -DUSE_MYSQLCPPCONN_GCOV_ENABLE=$(usex gcov ON OFF)
  38                 -DINSTALL_DOCS="/usr/share/doc/${PF}"
  39                 -DMYSQL_CXX_LINKAGE=0
  40                 -DMYSQL_INCLUDE_DIR=$(mysql_config --variable=pkgincludedir)
  41         )
  42
  43         cmake-utils_src_configure
  44 }
  45
  46 src_install() {
  47         cmake-utils_src_install
  48
  49         # static lib has wrong name so we need to rename it
  50         if use static-libs; then
  51                 mv "${ED}"/usr/$(get_libdir)/libmysqlcppconn-static.a \
  52                         "${ED}"/usr/$(get_libdir)/libmysqlcppconn.a || die
  53         else
  54                 rm -f "${ED}"/usr/$(get_libdir)/libmysqlcppconn-static.a
  55         fi
  56
  57         # examples
  58         if use examples; then
  59                 insinto /usr/share/doc/${PF}/examples
  60                 doins "${S}"/examples/*
  61         fi
  62 }