dev-db/mydumper/mydumper-0.9.3-r1.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit cmake-utils
   7
   8 DESCRIPTION="A high-performance multi-threaded backup (and restore) toolset for MySQL"
   9 HOMEPAGE="https://github.com/maxbube/mydumper"
  10 SRC_URI="https://github.com/maxbube/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11 LICENSE="GPL-3"
  12 SLOT="0"
  13 KEYWORDS="~amd64 ~x86"
  14 IUSE="doc"
  15
  16 CDEPEND="dev-libs/glib:=
  17         dev-libs/libpcre:=
  18         dev-libs/openssl:0=
  19         sys-libs/zlib:=
  20         virtual/mysql"
  21 DEPEND="${CDEPEND}
  22         virtual/pkgconfig
  23         doc? ( dev-python/sphinx )"
  24 RDEPEND="${CDEPEND}"
  25
  26 PATCHES=( "${FILESDIR}/${PN}-mariadb-define.patch" )
  27
  28 src_prepare() {
  29         # respect user cflags; do not expand ${CMAKE_C_FLAGS} (!)
  30         sed -i -e 's:-Werror -O3 -g:${CMAKE_C_FLAGS}:' CMakeLists.txt || die
  31
  32         # fix doc install path
  33         sed -i -e "s:share/doc/mydumper:share/doc/${PF}:" docs/CMakeLists.txt || die
  34
  35         cmake-utils_src_prepare
  36 }
  37
  38 src_configure() {
  39         local mycmakeargs=("-DBUILD_DOCS=$(usex doc)")
  40
  41         cmake-utils_src_configure
  42 }