dev-db/maatkit/maatkit-7540-r1.ebuild

   1 # Copyright 1999-2014 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=5
   5
   6 inherit perl-app perl-module toolchain-funcs
   7
   8 DESCRIPTION="essential command-line utilities for MySQL"
   9 HOMEPAGE="http://www.maatkit.org/"
  10 SRC_URI="https://maatkit.googlecode.com/files/${P}.tar.gz"
  11
  12 LICENSE="GPL-2"
  13 SLOT="0"
  14 KEYWORDS="amd64 x86 ~amd64-linux ~x86-linux ~ppc-macos"
  15 IUSE="udf"
  16
  17 COMMON_DEPEND="dev-perl/DBI
  18         dev-perl/DBD-mysql
  19         virtual/perl-Time-HiRes"
  20 RDEPEND="${COMMON_DEPEND}
  21         virtual/perl-Getopt-Long
  22         virtual/perl-Time-Local
  23         virtual/perl-Digest-MD5
  24         virtual/perl-IO-Compress
  25         virtual/perl-File-Temp
  26         virtual/perl-File-Spec
  27         virtual/perl-Time-HiRes
  28         virtual/perl-Scalar-List-Utils
  29         dev-perl/TermReadKey"
  30 DEPEND="${COMMON_DEPEND}
  31         udf? ( dev-db/mysql )
  32         virtual/perl-ExtUtils-MakeMaker"
  33
  34 mysql-udf_src_compile() {
  35         local udfdir="${T}/udf/"
  36         mkdir -p "${udfdir}"
  37
  38         local udfname udffile udfext udfoutpath
  39         udfname="${1}"
  40         udfext=".so"
  41         udffile="${udfname}${udfext}"
  42         udfoutpath="${udfdir}/${udffile}"
  43         shift
  44         CXX="$(tc-getCXX)"
  45         local src="$@"
  46         if [ -z "$@" ]; then
  47                 src="${udfname}.cc"
  48         fi
  49         for f in ${src} ; do
  50                 [ -f "${f}" ] || \
  51                         die "UDF ${udfname}: Cannot find source file ${f} to compile"
  52         done
  53         einfo "UDF ${udfname}: compiling from ${src}"
  54         ${CXX} \
  55                 ${CXXFLAGS} -I/usr/include/mysql \
  56                 ${LDFLAGS} -fPIC -shared -o "${udfoutpath}" $src \
  57                 || die "UDF ${udfname}: Failed to compile"
  58 }
  59
  60 mysql-udf_src_install() {
  61         local udfdir="${T}/udf/"
  62         local udfname udfext udffile udfoutpath
  63         udfname="${1}"
  64         udfext=".so"
  65         udffile="${udfname}${udfext}"
  66         udfoutpath="${udfdir}/${udffile}"
  67         insinto /usr/$(get_libdir)/mysql/plugins
  68         doins "${udfoutpath}"
  69 }
  70
  71 udf_done_intro=0
  72 mysql-udf_pkg_postinst() {
  73         local udfname udffile udfext udffunc udfreturn
  74         udfname="${1}"
  75         udfext=".so"
  76         udffile="${udfname}${udfext}"
  77         udffunc="${2}"
  78         udfreturn="${3}"
  79         if [ ${udf_done_intro} -eq 0 ]; then
  80                 elog "To use the UDFs that were built:"
  81                 elog "Update your configuration to include 'plugin_dir=/usr/$(get_libdir)/mysql/plugins'"
  82                 elog "Issue the following commands as a user with FUNCTION privileges:"
  83                 udf_done_intro=1
  84         fi
  85         elog "CREATE FUNCTION ${udffunc} RETURNS ${udfreturn} SONAME '${udffile}'"
  86 }
  87
  88 src_compile() {
  89         perl-app_src_compile
  90         if use udf; then
  91                 cd "${S}"/udf
  92                 mysql-udf_src_compile murmur_udf
  93                 mysql-udf_src_compile fnv_udf
  94         fi
  95 }
  96
  97 src_install() {
  98         perl-module_src_install
  99         if use udf; then
 100                 mysql-udf_src_install murmur_udf
 101                 mysql-udf_src_install fnv_udf
 102         fi
 103 }
 104
 105 pkg_postinst() {
 106         if use udf; then
 107                 mysql-udf_pkg_postinst murmur_udf murmur_hash INTEGER
 108                 mysql-udf_pkg_postinst fnv_udf fnv_64 INTEGER
 109         fi
 110 }