dev-db/lmdb/lmdb-0.9.23.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=7
   5
   6 inherit flag-o-matic multilib-minimal toolchain-funcs
   7
   8 DESCRIPTION="An ultra-fast, ultra-compact key-value embedded data store"
   9 HOMEPAGE="https://symas.com/lmdb/technical/"
  10 SRC_URI="https://github.com/LMDB/lmdb/archive/LMDB_${PV}.tar.gz"
  11
  12 LICENSE="OPENLDAP"
  13 SLOT="0/${PV}"
  14 KEYWORDS="~alpha amd64 arm arm64 hppa ia64 ~mips ppc ppc64 ~riscv ~s390 sparc x86 ~ppc-aix ~amd64-linux ~x86-linux ~ppc-macos ~x64-macos ~x86-macos ~x64-solaris ~x86-solaris"
  15 IUSE="static-libs"
  16
  17 DEPEND=""
  18 RDEPEND=""
  19
  20 S="${WORKDIR}/${PN}-LMDB_${PV}/libraries/liblmdb"
  21
  22 src_prepare() {
  23         eapply_user
  24         if [[ ${CHOST} == *-darwin* && ${CHOST#*-darwin} -lt 10 ]] ; then
  25                 # posix_memalign isn't available before 10.6, but on OSX
  26                 # malloc is always aligned for any addressable type
  27                 sed -i -e '/(__APPLE__)/a#define HAVE_MEMALIGN 1\n#define memalign(X,Y) malloc(X)' mdb.c || die
  28         fi
  29         multilib_copy_sources
  30 }
  31
  32 multilib_src_configure() {
  33         local soname="-Wl,-soname,liblmdb$(get_libname 0)"
  34         [[ ${CHOST} == *-darwin* ]] && \
  35                 soname="-dynamiclib -install_name ${EPREFIX}/usr/$(get_libdir)/liblmdb$(get_libname 0)"
  36         sed -i -e "s!^CC.*!CC = $(tc-getCC)!" \
  37                 -e "s!^CFLAGS.*!CFLAGS = ${CFLAGS}!" \
  38                 -e "s!^AR.*!AR = $(tc-getAR)!" \
  39                 -e "s!^SOEXT.*!SOEXT = $(get_libname)!" \
  40                 -e "/^prefix/s!/usr/local!${EPREFIX}/usr!" \
  41                 -e "/^libdir/s!lib\$!$(get_libdir)!" \
  42                 -e "s!shared!shared ${soname}!" \
  43                 "Makefile" || die
  44
  45         if [[ ${CHOST} == *-solaris* ]] ; then
  46                 # fdatasync lives in -lrt on Solaris 10
  47                 [[ ${CHOST#*-solaris2.} -le 10 ]] && append-ldflags -lrt
  48         fi
  49 }
  50
  51 multilib_src_compile() {
  52         emake LDLIBS+=" -pthread"
  53 }
  54
  55 multilib_src_install() {
  56         emake DESTDIR="${D}" install
  57
  58         mv "${ED}"/usr/$(get_libdir)/liblmdb$(get_libname) \
  59                 "${ED}"/usr/$(get_libdir)/liblmdb$(get_libname 0) || die
  60         dosym liblmdb$(get_libname 0) /usr/$(get_libdir)/liblmdb$(get_libname)
  61
  62         insinto /usr/$(get_libdir)/pkgconfig
  63         doins "${FILESDIR}/lmdb.pc"
  64         sed -i -e "s!@PACKAGE_VERSION@!${PV}!" \
  65                 -e "s!@prefix@!${EPREFIX}/usr!g" \
  66                 -e "s!@libdir@!$(get_libdir)!" \
  67                 "${ED}"/usr/$(get_libdir)/pkgconfig/lmdb.pc || die
  68
  69         if ! use static-libs; then
  70                 rm "${ED}"/usr/$(get_libdir)/liblmdb.a || die
  71         fi
  72 }