dev-cpp/gtkmm/gtkmm-3.24.2.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5 inherit gnome2 multilib-minimal virtualx
   6
   7 DESCRIPTION="C++ interface for GTK+"
   8 HOMEPAGE="https://www.gtkmm.org"
   9
  10 LICENSE="LGPL-2.1+"
  11 SLOT="3.0"
  12 KEYWORDS="~alpha amd64 arm ~arm64 ~hppa ~ia64 ppc ppc64 sparc x86 ~amd64-linux ~x86-linux ~x86-solaris"
  13
  14 IUSE="aqua doc test wayland X"
  15 REQUIRED_USE="|| ( aqua wayland X )"
  16 RESTRICT="!test? ( test )"
  17
  18 RDEPEND="
  19         >=dev-cpp/glibmm-2.54.0:2[${MULTILIB_USEDEP}]
  20         >=x11-libs/gtk+-3.24.0:3[aqua?,wayland?,X?,${MULTILIB_USEDEP}]
  21         >=x11-libs/gdk-pixbuf-2.35.5:2[${MULTILIB_USEDEP}]
  22         >=dev-cpp/atkmm-2.24.2[${MULTILIB_USEDEP}]
  23         >=dev-cpp/cairomm-1.12.0[${MULTILIB_USEDEP}]
  24         >=dev-cpp/pangomm-2.38.2:1.4[${MULTILIB_USEDEP}]
  25         >=dev-libs/libsigc++-2.3.2:2[${MULTILIB_USEDEP}]
  26 "
  27 DEPEND="${RDEPEND}
  28         virtual/pkgconfig
  29         doc? (
  30                 media-gfx/graphviz
  31                 dev-libs/libxslt
  32                 app-doc/doxygen )
  33 "
  34 # eautoreconf needs mm-common
  35
  36 RESTRICT="!test? ( test )"
  37
  38 src_prepare() {
  39         if ! use test; then
  40                 # don't waste time building tests
  41                 sed 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
  42                         || die "sed 1 failed"
  43         fi
  44
  45         # don't waste time building examples
  46         sed 's/^\(SUBDIRS =.*\)demos\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
  47                 || die "sed 2 failed"
  48
  49         gnome2_src_prepare
  50 }
  51
  52 multilib_src_configure() {
  53         ECONF_SOURCE="${S}" gnome2_src_configure \
  54                 --enable-api-atkmm \
  55                 $(multilib_native_use_enable doc documentation) \
  56                 $(use_enable aqua quartz-backend) \
  57                 $(use_enable wayland wayland-backend) \
  58                 $(use_enable X x11-backend)
  59 }
  60
  61 multilib_src_test() {
  62         virtx emake check
  63 }
  64
  65 multilib_src_install() {
  66         gnome2_src_install
  67 }
  68
  69 multilib_src_install_all() {
  70         einstalldocs
  71
  72         find demos -type d -name '.deps' -exec rm -rf {} \; 2>/dev/null
  73         find demos -type f -name 'Makefile*' -exec rm -f {} \; 2>/dev/null
  74         dodoc -r demos
  75 }