dev-cpp/gtkmm/gtkmm-2.24.5.ebuild

   1 # Copyright 1999-2016 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=6
   6
   7 inherit gnome2 multilib-minimal
   8
   9 DESCRIPTION="C++ interface for GTK+"
  10 HOMEPAGE="http://www.gtkmm.org"
  11
  12 LICENSE="LGPL-2.1+"
  13 SLOT="2.4"
  14 KEYWORDS="alpha amd64 ~arm ~hppa ~ia64 ~ppc ~ppc64 ~sh ~sparc x86 ~x86-fbsd ~x86-freebsd ~amd64-linux ~x86-linux ~sparc-solaris ~x86-solaris"
  15 IUSE="doc examples test"
  16
  17 COMMON_DEPEND="
  18         >=dev-cpp/glibmm-2.34.1:2[${MULTILIB_USEDEP}]
  19         >=x11-libs/gtk+-2.24.15:2[${MULTILIB_USEDEP}]
  20         >=x11-libs/gdk-pixbuf-2.28:2[${MULTILIB_USEDEP}]
  21         >=dev-cpp/atkmm-2.22.7[${MULTILIB_USEDEP}]
  22         >=dev-cpp/cairomm-1.10.0-r1[${MULTILIB_USEDEP}]
  23         >=dev-cpp/pangomm-2.34.0:1.4[${MULTILIB_USEDEP}]
  24         >=dev-libs/libsigc++-2.3.2:2[${MULTILIB_USEDEP}]
  25 "
  26 RDEPEND="${COMMON_DEPEND}
  27         abi_x86_32? (
  28                 !<=app-emulation/emul-linux-x86-gtkmmlibs-20140508
  29                 !app-emulation/emul-linux-x86-gtkmmlibs[-abi_x86_32(-)] )
  30 "
  31 DEPEND="${COMMON_DEPEND}
  32         virtual/pkgconfig[${MULTILIB_USEDEP}]
  33         doc? (
  34                 media-gfx/graphviz
  35                 dev-libs/libxslt
  36                 app-doc/doxygen )
  37 "
  38
  39 src_prepare() {
  40         if ! use test; then
  41                 # don't waste time building tests
  42                 sed 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
  43                         || die "sed 1 failed"
  44         fi
  45
  46         if ! use examples; then
  47                 # don't waste time building tests
  48                 sed 's/^\(SUBDIRS =.*\)demos\(.*\)$/\1\2/' -i Makefile.am Makefile.in \
  49                         || die "sed 2 failed"
  50         fi
  51
  52         gnome2_src_prepare
  53 }
  54
  55 multilib_src_configure() {
  56         ECONF_SOURCE="${S}" \
  57         gnome2_src_configure \
  58                 --enable-api-atkmm \
  59                 $(multilib_native_use_enable doc documentation)
  60 }
  61
  62 multilib_src_install() {
  63         gnome2_src_install
  64 }
  65
  66 multilib_src_install_all() {
  67         DOCS="AUTHORS ChangeLog PORTING NEWS README"
  68         einstalldocs
  69 }