dev-cpp/gtest/gtest-1.8.0-r1.ebuild

   1 # Copyright 1999-2020 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 # Python is required for tests and some build tasks.
   7 PYTHON_COMPAT=( python2_7 python3_6 )
   8
   9 inherit python-any-r1 cmake-multilib
  10
  11 DESCRIPTION="Google C++ Testing Framework"
  12 HOMEPAGE="https://github.com/google/googletest"
  13 SRC_URI="https://github.com/google/googletest/archive/release-${PV}.tar.gz -> ${P}.tar.gz"
  14
  15 LICENSE="BSD"
  16 SLOT="0"
  17 KEYWORDS="alpha amd64 arm arm64 hppa ia64 ~m68k ~mips ppc ppc64 s390 ~sh sparc x86 ~amd64-linux ~x86-linux ~ppc-macos"
  18 IUSE="doc examples test"
  19 RESTRICT="!test? ( test )"
  20
  21 DEPEND="test? ( ${PYTHON_DEPS} )"
  22 RDEPEND="!dev-cpp/gmock"
  23
  24 PATCHES=(
  25         "${FILESDIR}"/${PN}-9999-fix-py-tests.patch
  26         "${FILESDIR}"/${PN}-1.8.0-fix-gcc6-undefined-behavior.patch
  27         "${FILESDIR}"/${PN}-1.8.0-multilib-strict.patch
  28         "${FILESDIR}"/${PN}-1.8.0-increase-clone-stack-size.patch
  29         "${FILESDIR}"/${PN}-1.8.0-fix-doublefree.patch
  30 )
  31
  32 S="${WORKDIR}"/googletest-release-${PV}
  33
  34 pkg_setup() {
  35         use test && python-any-r1_pkg_setup
  36 }
  37
  38 multilib_src_configure() {
  39         local mycmakeargs=(
  40                 -DBUILD_GMOCK=ON
  41                 -DBUILD_GTEST=ON
  42                 -DLIB_INSTALL_DIR=$(get_libdir)
  43                 -Dgtest_build_samples=OFF
  44                 -Dgtest_disable_pthreads=OFF
  45                 -DBUILD_SHARED_LIBS=ON
  46
  47                 # tests
  48                 -Dgmock_build_tests=$(usex test)
  49                 -Dgtest_build_tests=$(usex test)
  50                 -DPYTHON_EXECUTABLE="${PYTHON}"
  51         )
  52         cmake-utils_src_configure mycmakeargs
  53 }
  54
  55 multilib_src_install_all() {
  56         einstalldocs
  57
  58         if use doc; then
  59                 docinto googletest
  60                 dodoc -r googletest/docs/*
  61                 docinto googlemock
  62                 dodoc -r googlemock/docs/*
  63         fi
  64
  65         if use examples; then
  66                 docinto examples
  67                 dodoc googletest/samples/*.{cc,h}
  68         fi
  69 }