dev-cpp/gstreamermm/gstreamermm-1.10.0.ebuild

   1 # Copyright 1999-2019 Gentoo Authors
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI=6
   5
   6 inherit gnome2 virtualx
   7
   8 DESCRIPTION="C++ interface for GStreamer"
   9 HOMEPAGE="https://gstreamer.freedesktop.org/bindings/cplusplus.html"
  10
  11 LICENSE="LGPL-2.1"
  12 SLOT="1.0/1"
  13 KEYWORDS="amd64 ~ppc x86"
  14 IUSE="doc examples test"
  15 RESTRICT="!test? ( test )"
  16
  17 RDEPEND="
  18         >=media-libs/gstreamer-${PV}:1.0
  19         >=media-libs/gst-plugins-base-${PV}:1.0
  20         >=dev-cpp/glibmm-2.47.6:2
  21         >=dev-cpp/libxmlpp-2.14:2.6
  22         >=dev-libs/libsigc++-2:2
  23 "
  24 DEPEND="${RDEPEND}
  25         dev-cpp/mm-common
  26         virtual/pkgconfig
  27         doc? (
  28                 app-doc/doxygen
  29                 dev-libs/libxslt
  30                 media-gfx/graphviz )
  31         test? (
  32                 dev-cpp/gtest
  33                 >=media-libs/gst-plugins-base-${PV}:1.0[X,ogg,theora,vorbis]
  34                 >=media-libs/gst-plugins-good-${PV}:1.0
  35                 >=media-plugins/gst-plugins-jpeg-${PV}:1.0 )
  36 "
  37 # eautoreconf:
  38 #       dev-cpp/mm-common
  39
  40 # Installs reference docs into /usr/share/doc/gstreamermm-1.0/
  41 # but that's okay, because the rest of dev-cpp/*mm stuff does the same
  42
  43 src_prepare() {
  44         if ! use examples; then
  45                 # don't waste time building examples
  46                 sed -e 's/^\(SUBDIRS =.*\)examples\(.*\)$/\1\2/' \
  47                         -i Makefile.am Makefile.in || die
  48         fi
  49
  50         sed -e 's/ -Werror/ /' -i tests/Makefile.am tests/Makefile.in || die
  51
  52         gnome2_src_prepare
  53 }
  54
  55 src_configure() {
  56         gnome2_src_configure \
  57                 $(use_enable doc documentation) \
  58                 $(use_enable test unittests)
  59 }
  60
  61 src_test() {
  62         # running tests in parallel fails
  63         virtx emake -j1 check
  64 }