dev-cpp/glog/glog-0.3.5.ebuild

   1 # Copyright 1999-2018 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3
   4 EAPI="6"
   5
   6 inherit autotools multilib-minimal
   7
   8 DESCRIPTION="Google's C++ logging library"
   9 HOMEPAGE="https://github.com/google/glog"
  10 SRC_URI="https://github.com/google/${PN}/archive/v${PV}.tar.gz -> ${P}.tar.gz"
  11
  12 LICENSE="BSD"
  13 SLOT="0"
  14 KEYWORDS="~alpha ~amd64 ~arm ~arm64 ~hppa ~ia64 ~m68k ~mips ~ppc ~ppc64 ~s390 ~sh ~sparc ~x86 ~amd64-linux ~x86-linux"
  15 IUSE="gflags static-libs test unwind"
  16
  17 RDEPEND="
  18         gflags? ( >=dev-cpp/gflags-2.0-r1[${MULTILIB_USEDEP}] )
  19         unwind? ( sys-libs/libunwind[${MULTILIB_USEDEP}] )"
  20 DEPEND="${RDEPEND}
  21         test? ( >=dev-cpp/gtest-1.8.0[${MULTILIB_USEDEP}] )"
  22
  23 PATCHES=(
  24         "${FILESDIR}"/${PN}-0.3.2-avoid-inline-asm.patch
  25         "${FILESDIR}"/${PN}-0.3.4-fix-build-system.patch
  26         "${FILESDIR}"/${PN}-0.3.4-fix-gcc5-demangling.patch
  27 )
  28
  29 src_prepare() {
  30         default
  31         eautoreconf
  32 }
  33
  34 multilib_src_configure() {
  35         ECONF_SOURCE="${S}" econf \
  36                 $(use_enable gflags) \
  37                 $(use_enable static-libs static) \
  38                 $(use_enable test gtest-config) \
  39                 $(use_enable unwind)
  40 }
  41
  42 multilib_src_install_all() {
  43         einstalldocs
  44
  45         # package provides .pc files
  46         find "${D}" -name '*.la' -delete || die
  47 }