dev-cpp/cairomm/cairomm-1.12.0-r1.ebuild

   1 # Copyright 1999-2017 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 GCONF_DEBUG="no"
   7
   8 inherit gnome2 multilib-minimal
   9
  10 DESCRIPTION="C++ bindings for the Cairo vector graphics library"
  11 HOMEPAGE="http://cairographics.org/cairomm"
  12
  13 LICENSE="LGPL-2+"
  14 SLOT="0"
  15 KEYWORDS="alpha amd64 arm hppa ~ia64 ppc ppc64 ~sh sparc x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
  16 IUSE="aqua doc +svg X"
  17
  18 RDEPEND="
  19         >=x11-libs/cairo-1.12.10[aqua=,svg=,X=,${MULTILIB_USEDEP}]
  20         >=dev-libs/libsigc++-2.5.1:2[${MULTILIB_USEDEP}]
  21 "
  22 DEPEND="${RDEPEND}
  23         virtual/pkgconfig
  24         doc? (
  25                 app-doc/doxygen
  26                 dev-libs/libxslt
  27                 media-gfx/graphviz )
  28 "
  29
  30 src_prepare() {
  31         # don't waste time building examples because they are marked as "noinst"
  32         sed -i 's/^\(SUBDIRS =.*\)examples\(.*\)$/\1\2/' Makefile.in || die
  33
  34         # don't waste time building tests
  35         # they require the boost Unit Testing framework, that's not in base boost
  36         sed -i 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' Makefile.in || die
  37
  38         gnome2_src_prepare
  39 }
  40
  41 multilib_src_configure() {
  42         ECONF_SOURCE="${S}" gnome2_src_configure \
  43                 --disable-tests \
  44                 $(multilib_native_use_enable doc documentation)
  45 }
  46
  47 multilib_src_install() {
  48         gnome2_src_install
  49 }