dev-cpp/cairomm/cairomm-1.10.0-r1.ebuild

   1 # Copyright 1999-2015 Gentoo Foundation
   2 # Distributed under the terms of the GNU General Public License v2
   3 # $Id$
   4
   5 EAPI=5
   6 GCONF_DEBUG="no"
   7
   8 inherit eutils gnome2 multilib-minimal
   9
  10 DESCRIPTION="C++ bindings for the Cairo vector graphics library"
  11 HOMEPAGE="http://cairographics.org/cairomm"
  12 SRC_URI="http://cairographics.org/releases/${P}.tar.gz"
  13
  14 LICENSE="LGPL-2+"
  15 SLOT="0"
  16 KEYWORDS="alpha amd64 arm hppa ia64 ppc ppc64 ~sh sparc x86 ~x86-fbsd ~amd64-linux ~x86-linux ~ppc-macos ~x86-macos ~x86-solaris"
  17 IUSE="doc +svg"
  18
  19 # FIXME: svg support is automagic
  20 COMMON_DEPEND="
  21         >=x11-libs/cairo-1.12.10[svg?,${MULTILIB_USEDEP}]
  22         >=dev-libs/libsigc++-2.3.2:2[${MULTILIB_USEDEP}]
  23 "
  24 RDEPEND="${COMMON_DEPEND}
  25         abi_x86_32? (
  26                 !<=app-emulation/emul-linux-x86-gtkmmlibs-20140508
  27                 !app-emulation/emul-linux-x86-gtkmmlibs[-abi_x86_32(-)] )
  28 "
  29 DEPEND="${COMMON_DEPEND}
  30         virtual/pkgconfig
  31         doc? (
  32                 app-doc/doxygen
  33                 dev-libs/libxslt
  34                 media-gfx/graphviz )
  35 "
  36
  37 src_prepare() {
  38         # don't waste time building examples because they are marked as "noinst"
  39         sed -i 's/^\(SUBDIRS =.*\)examples\(.*\)$/\1\2/' Makefile.in || die
  40
  41         # don't waste time building tests
  42         # they require the boost Unit Testing framework, that's not in base boost
  43         sed -i 's/^\(SUBDIRS =.*\)tests\(.*\)$/\1\2/' Makefile.in || die
  44
  45         gnome2_src_prepare
  46 }
  47
  48 multilib_src_configure() {
  49         ECONF_SOURCE="${S}" gnome2_src_configure \
  50                 --disable-tests \
  51                 $(multilib_native_use_enable doc documentation)
  52 }
  53
  54 multilib_src_install() {
  55         gnome2_src_install
  56 }