configure.ac

   1 # configure.ac for GPGME
   2 # Copyright (C) 2000 Werner Koch (dd9jn)
   3 # Copyright (C) 2001, 2002, 2003, 2004, 2005, 2006 g10 Code GmbH
   4 #
   5 # This file is part of GPGME.
   6 #
   7 # GPGME is free software; you can redistribute it and/or modify it
   8 # under the terms of the GNU Lesser General Public License as
   9 # published by the Free Software Foundation; either version 2.1 of the
  10 # License, or (at your option) any later version.
  11 #
  12 # GPGME is distributed in the hope that it will be useful, but WITHOUT
  13 # ANY WARRANTY; without even the implied warranty of MERCHANTABILITY
  14 # or FITNESS FOR A PARTICULAR PURPOSE.  See the GNU Lesser General
  15 # Public License for more details.
  16 #
  17 # You should have received a copy of the GNU Lesser General Public
  18 # License along with this program; if not, write to the Free Software
  19 # Foundation, Inc., 59 Temple Place - Suite 330, Boston, MA 02111-1307, USA
  20
  21 # (Process this file with autoconf to produce a configure script.)
  22 AC_PREREQ(2.59)
  23 min_automake_version="1.9.3"
  24
  25 # Version number: Remember to change it immediately *after* a release.
  26 #                 Make sure to run  "svn up" before a "make dist".
  27 #                 See below for the LT versions.
  28 #
  29 # The CVS version is usually the next intended release version with
  30 # the string "-cvs" appended.  The reason for this is that tests for a
  31 # specific feature can already be done under the assumption that the
  32 # CVS version is the most recent one in a branch.  To disable the CVS
  33 # version for the real release, just comment out the my_iscvs macro.
  34 # Note, that we are now using Subversion instead of CVS and append the
  35 # SVN revision number to the "cvs" suffix.  To make this most useful
  36 # for snapshot releases please do an "svn up" right before recreating
  37 # the configure script, so that a proper revision number for all files
  38 # is available when running a "make distcheck".
  39 m4_define(my_version, [1.1.3])
  40 m4_define(my_iscvs, yes)
  41 AC_INIT([gpgme], my_version[]m4_ifdef([my_iscvs], [-cvs[]m4_translit(
  42                [$Revision$],[Ra-z $:])]),
  43                [bug-gpgme@gnupg.org])
  44
  45 # LT Version numbers, remember to change them just *before* a release.
  46 #   (Code changed:                      REVISION++)
  47 #   (Interfaces added/removed/changed:  CURRENT++, REVISION=0)
  48 #   (Interfaces added:                  AGE++)
  49 #   (Interfaces removed/changed:        AGE=0)
  50 #
  51 LIBGPGME_LT_CURRENT=17
  52 # Subtract 2 from this value if you want to make the LFS transition an
  53 # ABI break.  [Note to self: Remove this comment with the next regular break.]
  54 LIBGPGME_LT_AGE=6
  55 LIBGPGME_LT_REVISION=1
  56
  57 # If the API is changed in an incompatible way: increment the next counter.
  58 GPGME_CONFIG_API_VERSION=1
  59
  60 NEED_GPG_VERSION=1.3.0
  61 NEED_GPGSM_VERSION=1.9.6
  62 ##############################################
  63
  64
  65 PACKAGE=$PACKAGE_NAME
  66 VERSION=$PACKAGE_VERSION
  67
  68 AC_CONFIG_SRCDIR(gpgme/gpgme.h)
  69 dnl FIXME: Enable this with autoconf 2.59.
  70 dnl AC_CONFIG_MACRO_DIR(m4)
  71 AM_CONFIG_HEADER(config.h)
  72 AM_INIT_AUTOMAKE($PACKAGE, $VERSION)
  73 AM_MAINTAINER_MODE
  74 AC_CANONICAL_HOST
  75
  76 # Enable GNU extensions on systems that have them.
  77 AC_GNU_SOURCE
  78
  79 AH_VERBATIM([_REENTRANT],
  80 [/* To allow the use of GPGME in multithreaded programs we have to use
  81   special features from the library.
  82   IMPORTANT: gpgme is not yet fully reentrant and you should use it
  83   only from one thread.  */
  84 #ifndef _REENTRANT
  85 # define _REENTRANT 1
  86 #endif])
  87
  88 AC_PROG_CC
  89
  90 AC_SUBST(LIBGPGME_LT_CURRENT)
  91 AC_SUBST(LIBGPGME_LT_AGE)
  92 AC_SUBST(LIBGPGME_LT_REVISION)
  93 AC_DEFINE_UNQUOTED(NEED_GPG_VERSION, "$NEED_GPG_VERSION",
  94                                      [Min. needed GnuPG version.])
  95 AC_DEFINE_UNQUOTED(NEED_GPGSM_VERSION, "$NEED_GPGSM_VERSION",
  96                                        [Min. needed GPGSM version.])
  97
  98 AC_SUBST(PACKAGE)
  99 AC_SUBST(VERSION)
 100 AC_DEFINE_UNQUOTED(PACKAGE, "$PACKAGE", [Name of this package])
 101 AC_DEFINE_UNQUOTED(VERSION, "$VERSION", [Version of this package])
 102
 103 # Don't default to build static libs.
 104 AC_DISABLE_STATIC
 105 AC_LIBTOOL_WIN32_DLL
 106 AC_LIBTOOL_RC
 107 AC_PROG_LIBTOOL
 108
 109 # For now we hardcode the use of version scripts.  It would be better
 110 # to write a test for this or even implement this within libtool.
 111 have_ld_version_script=no
 112 case "${host}" in
 113     *-*-linux*)
 114         have_ld_version_script=yes
 115         ;;
 116     *-*-gnu*)
 117         have_ld_version_script=yes
 118         ;;
 119 esac
 120 AM_CONDITIONAL(HAVE_LD_VERSION_SCRIPT, test "$have_ld_version_script" = "yes")
 121
 122 GPG_DEFAULT=no
 123 GPGSM_DEFAULT=no
 124 component_system=None
 125 have_dosish_system=no
 126 have_w32_system=no
 127 case "${host}" in
 128     *-mingw32*)
 129         # special stuff for Windoze NT
 130         have_dosish_system=yes
 131         have_w32_system=yes
 132         GPG_DEFAULT='c:\\gnupg\\gpg.exe'
 133         # XXX Assuan is not supported in this configuration.
 134         #GPGSM_DEFAULT='c:\\gnupg\\gpgsm.exe'
 135         #component_system='COM+'
 136         ;;
 137     *)
 138         AC_CHECK_PTH(1.2.0,,,no,have_pth=yes)
 139         if test "$have_pth" = yes; then
 140           AC_DEFINE(HAVE_PTH, ,[Define if we have Pth.])
 141         fi
 142         AC_CHECK_LIB(pthread,pthread_create,have_pthread=yes)
 143         if test "$have_pthread" = yes; then
 144           AC_DEFINE(HAVE_PTHREAD, ,[Define if we have pthread.])
 145         fi
 146
 147         # XXX: Probably use exec-prefix here?
 148 #       GPG_DEFAULT='/usr/bin/gpg'
 149 #       GPGSM_DEFAULT='/usr/bin/gpgsm'
 150         ;;
 151 esac
 152
 153 if test "$have_dosish_system" = yes; then
 154    AC_DEFINE(HAVE_DOSISH_SYSTEM,1,
 155              [Defined if we run on some of the PCDOS like systems
 156               (DOS, Windoze. OS/2) with special properties like
 157               no file modes])
 158 fi
 159 AM_CONDITIONAL(HAVE_DOSISH_SYSTEM, test "$have_dosish_system" = yes)
 160
 161 if test "$have_w32_system" = yes; then
 162    AC_DEFINE(HAVE_W32_SYSTEM,1, [Defined if we run on a W32 API based system])
 163 fi
 164 AM_CONDITIONAL(HAVE_W32_SYSTEM, test "$have_w32_system" = yes)
 165
 166 build_w32_glib=no
 167 AM_PATH_GLIB_2_0
 168 AC_ARG_ENABLE(w32-glib,
 169             AC_HELP_STRING([--enable-w32-glib], [build GPGME Glib for W32]),
 170             build_w32_glib=$withval)
 171 AM_CONDITIONAL(BUILD_W32_GLIB, test "$build_w32_glib" = yes)
 172
 173 AM_CONDITIONAL(HAVE_PTH, test "$have_pth" = "yes")
 174 AM_CONDITIONAL(HAVE_PTHREAD, test "$have_pthread" = "yes")
 175
 176
 177 # Checks for header files.
 178 AC_CHECK_HEADERS(sys/select.h)
 179
 180
 181 # Type checks.
 182 AC_C_INLINE
 183 AC_CHECK_SIZEOF(unsigned int)
 184 AC_SYS_LARGEFILE
 185 AC_TYPE_OFF_T
 186
 187 # Checks for compiler features.
 188 if test "$GCC" = yes; then
 189     CFLAGS="$CFLAGS -Wall -Wcast-align -Wshadow -Wstrict-prototypes"
 190     if test "$have_w32_system" = yes; then
 191        CFLAGS="$CFLAGS -mms-bitfields"
 192     fi
 193 fi
 194
 195 # Network library fun.
 196 AC_CHECK_FUNC(gethostbyname, , AC_CHECK_LIB(nsl, gethostbyname,
 197         [NETLIBS="-lnsl $NETLIBS"]))
 198 AC_CHECK_FUNC(setsockopt, , AC_CHECK_LIB(socket, setsockopt,
 199         [NETLIBS="-lsocket $NETLIBS"]))
 200 AC_SUBST(NETLIBS)
 201
 202 # Checks for library functions.
 203 AC_FUNC_FSEEKO
 204
 205 AC_REPLACE_FUNCS(vasprintf)
 206 if test "$ac_cv_func_vasprintf" != yes; then
 207   GNUPG_CHECK_VA_COPY
 208 fi
 209
 210 # Try to find a thread-safe version of ttyname().
 211 AC_REPLACE_FUNCS(ttyname_r)
 212 if test "$ac_cv_func_ttyname_r" != yes; then
 213   AC_MSG_WARN([
 214 ***
 215 *** ttyname() is not thread-safe and ttyname_r() does not exist
 216 ***])
 217 fi
 218
 219 # Try to find a thread-safe version of getenv().
 220 have_thread_safe_getenv=no
 221 jm_GLIBC21
 222 if test $GLIBC21 = yes; then
 223   have_thread_safe_getenv=yes
 224 fi
 225 if test $have_thread_safe_getenv = yes; then
 226   AC_DEFINE(HAVE_THREAD_SAFE_GETENV, [1], [Define if getenv() is thread-safe])
 227 fi
 228 have_getenv_r=no
 229 AC_CHECK_FUNCS(getenv_r, have_getenv_r=yes)
 230 if test $have_getenv_r = no && test $have_thread_safe_getenv = no; then
 231   AC_MSG_WARN([
 232 ***
 233 *** getenv() is not thread-safe and getenv_r() does not exist
 234 ***])
 235 fi
 236
 237 # For converting time strings to seconds since Epoch, we need the timegm
 238 # function.
 239 AC_CHECK_FUNCS(timegm)
 240 if test "$ac_cv_func_timegm" != yes; then
 241   AC_MSG_WARN([
 242 ***
 243 *** timegm() not available - a non-thread-safe kludge will be used
 244 *** and the TZ variable might be changed at runtime.
 245 ***])
 246 fi
 247
 248 # Checking for libgpg-error.
 249 AM_PATH_GPG_ERROR(0.5,, AC_MSG_ERROR([libgpg-error was not found]))
 250 AC_DEFINE(GPG_ERR_SOURCE_DEFAULT, GPG_ERR_SOURCE_GPGME,
 251           [The default error source for GPGME.])
 252
 253
 254
 255 # Checks for system services
 256 NO_OVERRIDE=no
 257 AC_ARG_WITH(gpg,
 258             AC_HELP_STRING([--with-gpg=PATH], [use GnuPG binary at PATH]),
 259             GPG=$withval, NO_OVERRIDE=yes)
 260 if test "$NO_OVERRIDE" = "yes" || test "$GPG" = "yes"; then
 261   GPG=
 262   NO_OVERRIDE=yes
 263   if test "$cross_compiling" != "yes"; then
 264     AC_PATH_PROG(GPG, gpg)
 265   fi
 266   if test -z "$GPG"; then
 267     GPG="$GPG_DEFAULT"
 268   fi
 269 fi
 270 if test "$GPG" = no; then
 271   if test "$NO_OVERRIDE" = "yes"; then
 272     if test "$cross_compiling" != "yes"; then
 273       AC_MSG_WARN([
 274 ***
 275 *** Could not find GnuPG, install GnuPG or use --with-gpg=PATH to enable it
 276 ***])
 277     else
 278       AC_MSG_ERROR([
 279 ***
 280 *** Can not determine path to GnuPG when cross-compiling, use --with-gpg=PATH
 281 ***])
 282     fi
 283   fi
 284 else
 285   AC_DEFINE_UNQUOTED(GPG_PATH, "$GPG", [Path to the GnuPG binary.])
 286   AC_SUBST(GPG)
 287 fi
 288 dnl Check for GnuPG version requirement.
 289 GPG_VERSION=unknown
 290 ok=maybe
 291 if test -z "$GPG" -o "x$GPG" = "xno"; then
 292   ok=no
 293 else
 294   if test "$cross_compiling" = "yes"; then
 295     AC_MSG_WARN([GnuPG version can not be checked when cross compiling])
 296     ok=no
 297   else
 298     if test ! -x "$GPG"; then
 299       AC_MSG_WARN([GnuPG not executable, version check disabled])
 300       ok=no
 301     fi
 302   fi
 303 fi
 304 if test "$ok" = "maybe"; then
 305   AC_MSG_CHECKING(for GnuPG >= $NEED_GPG_VERSION)
 306   req_major=`echo $NEED_GPG_VERSION | \
 307              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
 308   req_minor=`echo $NEED_GPG_VERSION | \
 309              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
 310   req_micro=`echo $NEED_GPG_VERSION | \
 311              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
 312   gpg_version=`$GPG --version | grep ^gpg`
 313   major=`echo $gpg_version | \
 314          sed 's/^gpg (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
 315   minor=`echo $gpg_version | \
 316          sed 's/^gpg (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
 317   micro=`echo $gpg_version | \
 318          sed 's/^gpg (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
 319   GPG_VERSION=`echo $gpg_version | sed 's/^gpg (GnuPG) //'`
 320
 321   if test "$major" -gt "$req_major"; then
 322     ok=yes
 323   else
 324     if test "$major" -eq "$req_major"; then
 325       if test "$minor" -gt "$req_minor"; then
 326         ok=yes
 327       else
 328         if test "$minor" -eq "$req_minor"; then
 329           if test "$micro" -ge "$req_micro"; then
 330             ok=yes
 331           fi
 332         fi
 333       fi
 334     fi
 335   fi
 336   if test "$ok" = "yes"; then
 337     AC_MSG_RESULT(yes)
 338   else
 339     AC_MSG_RESULT(no)
 340     AC_MSG_WARN([GnuPG must be at least version $NEED_GPG_VERSION])
 341   fi
 342 fi
 343 AM_CONDITIONAL(RUN_GPG_TESTS, test "$ok" = "yes")
 344 AC_SUBST(GPG_PATH)
 345
 346 NO_OVERRIDE=no
 347 AC_ARG_WITH(gpgsm,
 348             AC_HELP_STRING([--with-gpgsm=PATH], [use GpgSM binary at PATH]),
 349             GPGSM=$withval, NO_OVERRIDE=yes)
 350 if test "$NO_OVERRIDE" = "yes" || test "$GPGSM" = "yes"; then
 351   GPGSM=
 352   NO_OVERRIDE=yes
 353   if test "$cross_compiling" != "yes"; then
 354     AC_PATH_PROG(GPGSM, gpgsm)
 355   fi
 356   if test -z "$GPGSM"; then
 357     GPGSM="$GPGSM_DEFAULT"
 358   fi
 359 fi
 360 if test "$GPGSM" = no; then
 361   if test "$NO_OVERRIDE" = "yes"; then
 362     if test "$cross_compiling" != "yes"; then
 363       AC_MSG_WARN([
 364 ***
 365 *** Could not find GpgSM, install GpgSM or use --with-gpgsm=PATH to enable it
 366 ***])
 367     else
 368       AC_MSG_ERROR([
 369 ***
 370 *** Can not determine path to GpgSM when cross-compiling, use --with-gpgsm=PATH
 371 ***])
 372     fi
 373   fi
 374 else
 375   AC_DEFINE_UNQUOTED(GPGSM_PATH, "$GPGSM", [Path to the GPGSM binary.])
 376   AC_DEFINE(ENABLE_GPGSM,1,[Whether GPGSM support is enabled])
 377 fi
 378 AM_CONDITIONAL(HAVE_GPGSM, test "$GPGSM" != "no")
 379
 380
 381 dnl Check for GPGSM version requirement.
 382 GPGSM_VERSION=unknown
 383 ok=maybe
 384 if test -z "$GPGSM" -o "x$GPGSM" = "xno"; then
 385   ok=no
 386 else
 387   if test "$cross_compiling" = "yes"; then
 388     AC_MSG_WARN([GPGSM version can not be checked when cross compiling])
 389     ok=no
 390   else
 391     if test ! -x "$GPGSM"; then
 392       AC_MSG_WARN([GPGSM not executable, version check disabled])
 393       ok=no
 394     fi
 395   fi
 396 fi
 397 if test "$ok" = "maybe"; then
 398   AC_MSG_CHECKING(for GPGSM >= $NEED_GPGSM_VERSION)
 399   req_major=`echo $NEED_GPGSM_VERSION | \
 400              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\1/'`
 401   req_minor=`echo $NEED_GPGSM_VERSION | \
 402              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\2/'`
 403   req_micro=`echo $NEED_GPGSM_VERSION | \
 404              sed 's/\([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\)/\3/'`
 405   gpgsm_version=`$GPGSM --version | grep ^gpgsm`
 406   major=`echo $gpgsm_version | \
 407          sed 's/^gpgsm (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\1/'`
 408   minor=`echo $gpgsm_version | \
 409          sed 's/^gpgsm (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\2/'`
 410   micro=`echo $gpgsm_version | \
 411          sed 's/^gpgsm (GnuPG) \([[0-9]]*\)\.\([[0-9]]*\)\.\([[0-9]]*\).*/\3/'`
 412   GPGSM_VERSION=`echo $gpgsm_version | sed 's/^gpgsm (GnuPG) //'`
 413
 414   if test "$major" -gt "$req_major"; then
 415     ok=yes
 416   else
 417     if test "$major" -eq "$req_major"; then
 418       if test "$minor" -gt "$req_minor"; then
 419         ok=yes
 420       else
 421         if test "$minor" -eq "$req_minor"; then
 422           if test "$micro" -ge "$req_micro"; then
 423             ok=yes
 424           fi
 425         fi
 426       fi
 427     fi
 428   fi
 429   if test "$ok" = "yes"; then
 430     AC_MSG_RESULT(yes)
 431   else
 432     AC_MSG_RESULT(no)
 433     AC_MSG_WARN([GPGSM must be at least version $NEED_GPGSM_VERSION])
 434   fi
 435 fi
 436 AM_CONDITIONAL(RUN_GPGSM_TESTS, test "$ok" = "yes")
 437
 438 # FIXME: Only build if supported.
 439 AM_CONDITIONAL(BUILD_ASSUAN, test "$GPGSM" != "no")
 440
 441
 442 # The assuan code uses funopen but it will also build without it.  So
 443 # test for it.  Frankly, this is not required in gpgme, but thats the
 444 # way we handle it in libassuan.
 445 AC_CHECK_FUNCS(funopen)
 446 if test $ac_cv_func_funopen != yes; then
 447     # No funopen but we can implement that in terms of fopencookie.
 448     AC_CHECK_FUNCS(fopencookie)
 449     if test $ac_cv_func_fopencookie = yes; then
 450         AC_LIBOBJ([funopen])
 451     else
 452         AC_MSG_WARN([
 453 ***
 454 *** No implementation of fopencookie or funopen available
 455 ***])
 456     fi
 457 fi
 458
 459 # More assuan replacement functions.
 460 AC_REPLACE_FUNCS(isascii)
 461 AC_REPLACE_FUNCS(putc_unlocked)
 462 AC_REPLACE_FUNCS(memrchr)
 463 AC_REPLACE_FUNCS(stpcpy)
 464 # Check for unistd.h for setenv replacement function.
 465 AC_CHECK_HEADERS(unistd.h)
 466 AC_REPLACE_FUNCS(setenv)
 467
 468 # More assuan checks.
 469 AC_CHECK_HEADERS([sys/uio.h])
 470
 471 # Assuan check for descriptor passing.
 472 AC_CHECK_MEMBER(struct cmsghdr.cmsg_len,
 473                 [use_descriptor_passing=yes],
 474                 [use_descriptor_passing=no
 475                  AC_MSG_WARN([
 476 ***
 477 *** Data structure for sending ancillary data missing.
 478 *** Descriptor passing won't work.
 479 ***])],[
 480 #include <stdlib.h>
 481 #include <stddef.h>
 482 #include <stdio.h>
 483 #include <sys/types.h>
 484 #include <sys/socket.h>
 485 #include <sys/un.h>
 486 #if HAVE_SYS_UIO_H
 487 #include <sys/uio.h>
 488 #endif
 489 #include <unistd.h>
 490        ])
 491 if test "$use_descriptor_passing" = "yes"; then
 492  AC_DEFINE(USE_DESCRIPTOR_PASSING, 1,
 493             [Defined if descriptor passing is supported])
 494 fi
 495 AM_CONDITIONAL(USE_DESCRIPTOR_PASSING, test "$use_descriptor_passing" = "yes")
 496
 497 # End of assuan checks.
 498
 499 AM_CONDITIONAL(BUILD_COMPLUS, test "$component_system" = "COM+")
 500
 501 # Make the version number in gpgme/gpgme.h the same as the one here.
 502 # (this is easier than to have a *.in file just for one substitution)
 503 GNUPG_FIX_HDR_VERSION(gpgme/gpgme.h, GPGME_VERSION)
 504
 505 # Generate values for the DLL version info
 506 changequote(,)dnl
 507 BUILD_REVISION="`echo '$Revision$' | sed 's/[^0-9]//g'`"
 508 changequote([,])dnl
 509 test -z "$BUILD_REVISION" && BUILD_REVISION="0"
 510 if test "$have_w32_system" = yes; then
 511     BUILD_TIMESTAMP=`date --iso-8601=minutes`
 512     changequote(,)dnl
 513     BUILD_FILEVERSION=`echo "$VERSION" | sed 's/\([0-9.]*\).*/\1./;s/\./,/g'`
 514     changequote([,])dnl
 515     BUILD_FILEVERSION="${BUILD_FILEVERSION}${BUILD_REVISION}"
 516 fi
 517 AC_SUBST(BUILD_REVISION)
 518 AC_SUBST(BUILD_TIMESTAMP)
 519 AC_SUBST(BUILD_FILEVERSION)
 520
 521 # Add a few constants to help porting to W32
 522 AH_VERBATIM([SEPCONSTANTS],
 523 [
 524 /* Separators as used in file names and $PATH. Please note that the
 525    string version must not contain more than one character because
 526    the using code assumes strlen()==1 */
 527 #ifdef HAVE_DOSISH_SYSTEM
 528 #define DIRSEP_C '\\\\'
 529 #define EXTSEP_C '.'
 530 #define DIRSEP_S "\\\\"
 531 #define EXTSEP_S "."
 532 #define PATHSEP_C ';'
 533 #define PATHSEP_S ";"
 534 #else
 535 #define DIRSEP_C '/'
 536 #define EXTSEP_C '.'
 537 #define DIRSEP_S "/"
 538 #define EXTSEP_S "."
 539 #define PATHSEP_C ':'
 540 #define PATHSEP_S ":"
 541 #endif
 542 ])
 543
 544 AH_BOTTOM([
 545 /* Definition of GCC specific attributes.  */
 546 #if __GNUC__ > 2
 547 # define GPGME_GCC_A_PURE  __attribute__ ((__pure__))
 548 #else
 549 # define GPGME_GCC_A_PURE
 550 #endif
 551 ])
 552
 553
 554 # Substitution used for gpgme-config
 555 GPGME_CONFIG_LIBS="-lgpgme"
 556 GPGME_CONFIG_CFLAGS=""
 557 AC_SUBST(GPGME_CONFIG_API_VERSION)
 558 AC_SUBST(GPGME_CONFIG_LIBS)
 559 AC_SUBST(GPGME_CONFIG_CFLAGS)
 560
 561 # Frob'da Variables
 562 LTLIBOBJS=`echo "$LIB@&t@OBJS" |
 563            sed 's,\.[[^.]]* ,.lo ,g;s,\.[[^.]]*$,.lo,'`
 564 AC_SUBST(LTLIBOBJS)
 565
 566 #
 567 # Create config files
 568
 569 AC_CONFIG_FILES(Makefile assuan/Makefile gpgme/Makefile
 570                 tests/Makefile tests/gpg/Makefile tests/gpgsm/Makefile
 571                 doc/Makefile complus/Makefile
 572                 gpgme/versioninfo.rc)
 573 AC_CONFIG_FILES(gpgme/gpgme-config, chmod +x gpgme/gpgme-config)
 574 AC_CONFIG_FILES([lang/Makefile lang/cl/Makefile lang/cl/gpgme.asd])
 575 AC_OUTPUT
 576
 577 echo "
 578         GPGME v${VERSION} has been configured as follows:
 579
 580         GnuPG path:    $GPG
 581         GnuPG version: $GPG_VERSION, min. $NEED_GPG_VERSION
 582
 583         GpgSM path:    $GPGSM
 584         GpgSM version: $GPGSM_VERSION, min. $NEED_GPGSM_VERSION
 585
 586         GPGME Pthread: $have_pthread
 587         GPGME Pth:     $have_pth
 588 "